4.2 - Friendly Ghosts (Patreon)

Well, I am working on path 4.2, which is in truly in a patchwork shape right now. But there is enough finished on this particular path where you decide to pay a quiet little visit to Hollow Ground (no fear, there are many less quiet or friendly options too). As always, not finished, no stats, more options to be coming. Just thought you might enjoy having a little chat with the kingpin himself. About 8800 words.

---

Wonderful, wonderful. It's going to be one of those nights when everything just clicks into shape for you. Like a fight flowing your way, with you one step ahead of the opposition. With the alarms out and the dampeners out of the way, you can feel the house surrounding you with quiet. No guards in here, unless you count the bodyguard, Jake Manalo you think it was. Asleep on the job though, which isn't very professional of him, and worse, in bed with the boss's girlfriend which is even less professional. You need to pause to make sure you got that right, but his thoughts and Nocturnes are closely enough entwined you don't think you're wrong about that. And, even more interesting, from what you can tell they are in the master bedroom. As is Hollow Ground.

Huh. Interesting. Looks like the bodyguard has a cushier job than reputation would have it.

It feels like it would be rude to wake everyone up, there's no need for that when you're here for a private chat. Would be better to have that between four eyes, and let the others sleep. You don't even need to put them to sleep, all you need to do is to make sure they won't wake up. You put the Rat-King on that duty, making sure they will alert you if there's any sign of stirring from the other two. Hollow Ground you can handle yourself.

Very, very carefully you brush your fingers over the sleeping mind of the Kingpin of Los Diablos, making sure not to make direct contact. You can feel the the dangerous tangle of thoughts there, whatever goes on in that mind has power, a ticking bomb with all the wires unmarked. It would be unwise to rouse it before you know what it can do. All you want is a chat, but to do that you need ${hghim} to wake up and... ah, yes. There. Dry mouth. Sleeping with an open mouth. Thirst. The second most common reason to wake up in the middle of the night, but you really don't want to ambush someone on the toilet. That seems rude somehow.

Instead you gently tug the sensation of thirst to the surface, waiting patiently for a minute or two for it to take hold. As you thought, that's all it takes for Hollow Ground to untangle ${hghim}self from the covers (and the other bodies?) and head towards the kitchen. Where...

*fake_choice

  #...I'm seated at the kitchen table, waiting for ${hghim}.

    Everything has gone smoothly to this point, and you don't want to alarm Hollow Ground more than necessary. There might have been alarms you missed, or other defensive systems. Might as well do your best to put ${hghim} at ease. Sitting down usually helps. The chairs are good quality, unlikely to break under the 

    *if suit_armor

      considerable

    weight of your armor. You pull one out and sits down, resting your hands in front of you on the table, as if you were waiting for the cards to be dealt. An apt analogy.

    As expected, the hapless Kingpin of Los Diablos doesn't suspect a thing as ${hghe} @{hgsv shuffles|shuffle} through the door, silk dressing gown carelessly thrown over ${hghis} shoulders leaving little to the imagination. It's at that moment you realize that you were very lucky that Hollow Ground bothered to get dressed at all before going to the kitchen, otherwise this would have been far more embarrassing for both of you. As it is, you still dim your HUD as ${hghis} hand @{hgsv fumbles|fumble} for the light switch, flicking on the lights. $!{hghe} @{hgsv mutters|mutter}a curse and @{hgsv rubs|rub} ${hghis} eyes, as you do your best to look away until ${hghe} realizes ${hghe} @{hgsv has|have} company. 

    "What the...?" Hollow Ground blinks like an owl woken up in the middle of the day, trying to make sense of what ${hghe}@{hgsv 's| are} looking at.

    *if suit_mysterious

      Even in the light, it takes ${hghis} eyes a moment to focus on you, at this point you are very good at remaining unnoticed even in plain sight.

    *elseif suit_functional

      $!{hghis} brows furrow as ${hghe} @{hgsv tries|try} to make sense of what ${hghe} @{hgsv is|are} seeing. You can't blame ${hghim} for being confused, so you try a little wave to see if that puts ${hghim} at ease.

    *else

      $!{hghis} body @{hgsv reacts|react} before ${hghis} mind @{hgsv does|do}. A step back, a gasp of surprise tinged with fear, the instinctive reaction of finding someone like you standing stock-still in ${hghis} kitchen in the middle of the night. You know exactly what kind of reaction your armor was created to provoke. Hollow Ground performs it admirably.

    "Don't be alarmed," you offer, though you suppose words do little at this point. "You know who I am, I suppose?"

    "$!{villain_name}."

    *if ((infamy >= 75) or (suit_terrifying))

      You can see the panic in ${hghis} eyes as ${hghe} instinctively steps back to flee. Interesting. No reflex to attack, is the Kingpin of Los Diablos a coward? It sure looks that way, you can smell the fear even through your air scrubbers.

    *else

      You can hear the confusion in ${hghis} voice though ${hghe} @{hgsv is|are} hiding it well.

    "What are you doing here?" $!{hghe} @{hgsv takes|take} a step back and @{hgsv pulls|pull} the robe closed around ${hghim}

    "Have a seat," you say instead, indicating the chair in front of you. "That way we can have talk more comfortably."

  #...I'm standing beside the door, ready to close it behind ${hghim}.

    Even though you want to have a talk, it wouldn't be the worst idea to drive home exactly how close Hollow Ground came to death. You doubt ${hghe} will spot you in the darkness, and with the door closed behind the two of you, there's less chance of ${hghim} bolting. 

    As expected, the hapless Kingpin of Los Diablos doesn't suspect a thing as ${hghe} @{hgsv shuffles|shuffle} through the door, silk dressing gown carelessly thrown over ${hghis} shoulders. It's at that moment you realize that you were very lucky that Hollow Ground bothered to get dressed at all before going to the kitchen, otherwise this would have been far more embarrassing for both of you. $!{hghis} hand @{hgsv fumbles|fumble} for the light switch, nearly touching you as ${hghe} @{hgsv flicks|flick} on the lights. $!{hghe} @{hgsv mutters|mutter}a curse and @{hgsv rubs|rub} ${hghis} eyes. Your HUD adapts instantly, and you smile as you keep still and silent until ${hghe} @{hgsv steps|step} fully inside. Then you close the door behind ${hghim}.

    "What the...?" Hollow Ground turns around at the noise, still blinking like an owl woken up in the middle of the day.

    *if suit_mysterious

      Even in the light, it takes ${hghis} eyes a moment to focus on you, at this point you are very good at remaining unnoticed even in plain sight.

    *elseif suit_functional

      $!{hghis} brows furrow as ${hghe} @{hgsv tries|try} to make sense of what ${hghe} @{hgsv is|are} seeing. You can't blame ${hghim} for being confused, you suppose.

    *else

      $!{hghis} body @{hgsv reacts|react} before ${hghis} mind @{hgsv does|do}. A step back, a gasp of surprise tinged with fear, the instinctive reaction of finding someone like you standing stock-still in ${hghis} kitchen in the middle of the night. You know exactly what kind of reaction your armor was created to provoke. Hollow Ground performs it admirably.

    "You are lucky I don't want you dead," you say, pleased with the way your vocal distorters make ${hghim} take a step back and pull the robe closed around ${hghim} as if the thin fabric could protect ${hghim} if you wanted to hurt ${hghim}.

    "$!{villain_name}."

    *if (((infamy >= 70) or (massacre)) or (suit_terrifying))

      You can see the panic in ${hghis} eyes as ${hghe} instinctively steps back to flee. Interesting. No reflex to attack, is the Kingpin of Los Diablos a coward? It sure looks that way, you can smell the fear even through your air scrubbers. Tasty.

    *else

      You can taste the fear in ${hghis} voice though ${hghe} @{hgsv is|are} hiding it well. It's only the fact that ${hghe} @{hgsv is|are} still alive that @{hgsv keeps|keep} ${hghim} from running. You must want ${hghim} alive.

    "Don't run," you warn, taking a step forward, echoed by Hollow Ground taking a step back at the same time. "Sit down." Simple orders, easy to obey even for a sleep addled

    *if (((infamy >= 70) or (massacre)) or (suit_terrifying))

      and terrified

    mind.

    *set hgscared true

  #...I've started making some coffee.

    If you know anything, it is that people who are only half awake are susceptible to weirdness. Is it a dream? Is it reality? Who can tell? Having ${villain_name} making coffee in ${hghis} kitchen will likely make Hollow Ground at least pause to wonder if ${hghe} @{hgsv is|are} dreaming before trying to sound the alarm.

    *if vice = "coffee"

      Besides, this is a brand of coffee you haven't tried before, might as well see if it's worth the price.

    You've left the lights off, the nightvision in your HUD makes it easy to navigate the kitchen regardless. The gentle sounds of the coffee machine doesn't seem to alarm Hollow Ground as ${hghe} @{hgsv shuffles|shuffle} through the door, a silk dressing gown carelessly thrown over ${hghis} shoulders. It's at that moment you realize that you were very lucky that Hollow Ground bothered to get dressed at all before going to the kitchen, otherwise this would have been far more embarrassing for both of you. $!{hghis} hand @{hgsv fumbles|fumble} for the light switch, flicking on the lights. $!{hghe} @{hgsv mutters|mutter}a curse and @{hgsv rubs|rub} ${hghis} eyes in response to the sudden light. Your HUD adapts instantly, and you smile as you keep still and silent, leaning against the kitchen counter.

    "What the...?" Hollow Ground finally realizes that something is wrong, that the smell of coffee is hiding an intruder lurking in plain sight.

    *if suit_mysterious

      Even then, it takes ${hghis} eyes a moment to focus on you, at this point you are very good at remaining unnoticed even when people are looking directly at you.

    *elseif suit_functional

      $!{hghis} brows furrow as ${hghe} @{hgsv tries|try} to make sense of what ${hghe} @{hgsv is|are} seeing. You can't blame ${hghim} for being confused, you suppose.

    *else

      $!{hghis} body @{hgsv reacts|react} before ${hghis} mind @{hgsv does|do}. A step back, a gasp of surprise tinged with fear, the instinctive reaction of finding someone like you standing in ${hghis} kitchen in the middle of the night. You know exactly what kind of reaction your armor was created to provoke. Hollow Ground performs it admirably.

    "You look like you need some coffee," you offer generously. "I thought I'd get some started early."

    "$!{villain_name}."

    *if ((infamy >= 75) or (suit_terrifying))

      You can see the panic in ${hghis} eyes as ${hghe} instinctively steps back to flee. Interesting. No reflex to attack, is the Kingpin of Los Diablos a coward? It sure looks that way, you can smell the fear even through your air scrubbers.

    *else

      You can hear the confusion in ${hghis} voice though ${hghe} @{hgsv is|are} hiding it well.

    "What are you doing here?" $!{hghe} @{hgsv takes|take} a step back and @{hgsv pulls|pull} the robe closed around ${hghim}

    "Making coffee," you repeat, slowly, as if talking to a child. "You shold probably take a seat "

    *set hgcoffee true

Hollow Ground hesitates, but then reluctantly pulls out a chair at the kitchen table and sits down. $!{hghis} eyes doesn't leave yours, though ${hghe} @{hgsv rubs|rub} one hand nervously.

*if hgknown_telepath

  "If you're planning to influence my mind, you're not going to be able to do that."

  *if not(known_telepath)

    Interesting. Looks like Hollow Ground knows more than most about your powers.

*else

  "If this is intended to intimidate me, it's not working."

"You were the one that wanted a meeting," you point out,

*if hgcoffee

  pouring a mug for ${hghim} now that the coffee is finished. "Milk or sugar?"

  "Black," ${hghe} @{hgsv sighs|sigh}. "It sounds like I want to be awake for this." 

  "Of course." You place the mug in front of ${hghim}, sitting down as well. The table is not much protection between you, but it seems to make ${hghim} feel better. Or perhaps that's the coffee in ${hghis} hands.

  *if vice = "coffee"

    You wish you could join ${hghim}, but that would mean taking your helmet off.

*elseif hgscared

  still leaning against the door. "Be careful what you wish for."

*else

  leaning back in your chair. The table is not much protection between you, but it seems to make ${hghim} feel better. 

"A meeting. Of course." Hollow Ground pulls at the lapels of ${hghis} robe, doing ${hghis} best to straighten it out. But there is no hiding 

*if gender = "woman"

  the sleep-ruffled ${hgcolor} hair or the lack of makeup.

*elseif gender = "man"

  the bags under the ${eyes} eyes.

*else

  the sleep-ruffled ${hgcolor} hair and the bags under the ${eyes} eyes.

*fake_choice

  #"I prefer it when I pick the setting," I say coldly.

    "I prefer it when I pick the setting." You keep your voice reasonable but cold. Hollow Hround tried to order you around, and was not above going after your puppet when ${hghe} failed. It's time that ${hghe} learned who was in control here.

    "And that you have." Hollow Ground looks out over the still lawn, no sign of alarm, no sign of guards, though the poolhouse blocks the view to the gates. "How much of a mess did you make on the way in?"

    "Not more than needed. Believe it or not, I am here to talk."     

  #"You tried to have my assistant killed," I say sharply

    "You tried to have my assistant killed," you say, your vocal distorters turning the sentence into a threat. "You should be glad I'm not here to burn this place down around you."

    "I am." Hollow Ground looks out over the still lawn, no sign of alarm, no sign of guards, though the poolhouse blocks the view to the gates. "How much of a mess did you make on the way in?"

    "Not as much as I wanted to. Whether I make more on the way out depends on you." You let the last word rest in silence for a few moments, before you continue. "Despite my instincts, I am here to talk."

  #"And in person, like you wanted to," I say amiably.

    "And in person too, like you wanted to." You smile under your helmet, though you doubt your vocal distorters managed to pick that up.

    "I guess expecting you to adhere to business hours was hoping for too much." Hollow Ground looks out over the still lawn, no sign of alarm, no sign of guards, though the poolhouse blocks the view to the gates. "How much of a mess did you make on the way in?"

    "Not more than needed. I'm just here to talk."

*if thief 

  "I suppose I should have expected this. You have a reputation for getting into places you shouldn't be."

  *if ((puppetauction) or (sneakyauction))

    $!{hghe} @{hgsv has|have} the look of someone about to refurbish ${hghis} whole security system.

  *else

    $!{hghe} @{hgsv glares|glare} at you, and you suppose you can't really blame ${hghim}. You've made a habit of trespassing on ${hghis} turf by now.

  "I'm flattered," you smirk. "And you should. Secrets can only protect someone until they are found out."

*else

  "I must admit I hadn't expected you to simply show up in my kitchen." $!{hghe} @{hgsv has|have} the look of someone about to refurbish ${hghis} whole security system. 

  *if (((galaboom) or (mayhem)) or ((hgbomb) or (blazeblaze)))

    "You have a more... explosive reputation."

    "What can I say, I'm playing nice." You lower your helmet in mock-humility, before you resume staring ${hghim} down. "Something you should be thankful for. Secrets only protects people until they are found out."

  *else

    "Congratulations. Few people manage to surprise me."

    "What can I say, I'm not most people." Or even people, which makes you smile to yourself under your helmet. "You should be more careful by the way, secrets only protect people until they are found out."

"Noted." Hollow Ground looks disturbed at that, which is no wonder. How long have ${hghe} been coasting on being nothing but a rumor?  You keep waiting for the mental impression to hit you as well, that's usually when you know what really bothers people. But instead, ${hghe} @{hgsv remains|remain} blank, in control. 

*if hgrep >= 55

  "I wanted to meet you because I was impressed by what you had accomplished so far, and yet you manage to exceed my expectations."

*else

  "It is obvious that I underestimated your abilities. A humbling lesson."

"Flattery, flattery." It is fascinating to watch ${hghim} act as if ${hghe} was in control, as if ${hghe} @{hgsv was|were} as dressed up as ${hghe} had been at the club.

*if hgknown_telepath

  You can't read ${hghis} mind, at least not without exerting actual force to do it. There might be time for that later, but right now ${hghis} face is telling you enough.

*else

  $!{hghis} thoughts are calm, no fear for ${hghis} life,

  *if hgscared

    the fright you gave ${hghim} earlier seems to have passed.

  *elseif hgcoffee

    sipping ${hghis} coffee.

  *else

    if you wanted ${hghim} dead  ${hghe} would already be so.

"But turnabout is fair play, don't you think? You wanted me without my armor, and instead here we have you. In the flesh."

*if suit_terrifying

  The way you say those words do make ${hghim} twitch uneasily.

"I would have preferred more than a dressing gown," ${hghe} @{hgsv admits|admit}, gesturing to ${hghim}self. "Though I won't let that bother me, I've made more important deals wearing less." The smile is sharp, shark-like and cocky.

And familiar.

You noticed when you met ${hghe} in your puppet, but everything tends to get filtered and skewed though ${phis} eyes. There's something so unnerving about Hollow Ground's appearance, especially now that there's nothing to distract from ${hghis} true face. It reminds you of how you look in the mornings when you try to avoid looking at yourself in the mirror. Not identical, but an echo of an echo, a smile reflected with enough familiarity to make you think.

Is this a coincidence? 

*fake_choice

  #Ignore it. I'll keep my distance.

    There are enough weird things in your life to investigate small things like this. You're here for a reason, focus on that and don't allow yourself to get distracted.

    *goto whyhere

  #It's weird alright, makes me itchy.

    You do look like Hollow Ground, and that is weird enough to make your palms itch. Not only the superficial differences of skin, hair and eyes, but the more subtle things. The way ${hghis} smile creases, the cheekbones, the nose... too many pieces of a similar puzzle.

  #Could this be genetic? You don't know what material the Farm used.

    Could this be something more than your imagination? You don't know what the Farm used when they brewed you up. What genetic material that went in the mixer. Could they have used some of Hollow Ground's? $!{hghe}'s a boost, so it can't have been much in that case, that much you know. The boost drug makes things unstable and prone to breakdown, otherwise the Farm could have cloned an endless army of super soldiers with no effort. But a little bit? A little spice? Is that possible?

The bigger question is what you're going to do about it. If you choose to reveal your face, would Hollow Ground have the same reaction as you do? Would ${hghe} be intrigued? If you seek to ally ${hghim} more closely that won't hurt. Revealing your face would be a sign of trust as well. Showing your own vulnerability as you have shown ${hghim} ${hghis}.

There's no cameras in here. Nothing to record you. Everyone else is still sleeping. What should you do?

*fake_choice

  #I keep the helmet on, it's not worth the risk to pry.

    If there is something more to your superficial likeness, that can be examined later, under safer circumstances. You're here for a reason, focus on that and don't allow yourself to get distracted.

    *goto whyhere

  #I will remove the helmet, and see what ${hghis} reaction will be.

    You can learn a lot from how people react, maybe this is a reckless decision but so was deciding to break in to this place. Revealing your face might be worth it in the long run, if nothing else it might make ${hghim} relax ${hghis} guard.

"Well," you reply, your thoughts having run quick enough that the delay is almost imperceptible. "If you are that relaxed in a less formal dressing, I might as well respond in kind." 

*if hgscared

  You leave your post by the door, walking over to sit down at the table as well. $!{hghe} doesn't move as you do, but you can see ${hghim} tense up. Finally, you

*else

  You

reach up to your helmet, releasing the locks. The sharp click sounds loud in the silence of the kitchen, and your voice goes from distorted to natural as you continue.

*if hgcoffee

  "That coffee is smelling too good not to have myself a cup."

*elseif hgscared

  "I think I've made my point by now."

*else

  "Things are easier meeting face to face."

You put down your helmet on the table, placing your hand on top of it as you watch Hollow Ground's eyes widen, nearly imperceptibly.

"I have to admit, I did not expect that," ${hghe} @{hgsv says|say}, a not of respect at your reckless act. "If you have no issues with showing me your face, why send an intermediary in the first place?"

*set hgreveal true

*fake_choice

  #"I do not like to be ordered around." I stress the 'not'.

    "I do [b]not[/b] like to be ordered around," you say, your voice nearly as harsh as if it had been filtered through your distorters. "You'd do well to remember that."

    "I will." The way Hollow Ground speaks those words makes it feel half threat and half promise. Right now it doesn't matter. All empty words, the ball is in your court this time. "And neither do I."

    "Which is why I didn't bother inviting you on my turf," you offer with a thin smile. "I came to you. In your house. Mighty generous if you ask me."

    "Proving a point, if you ask me." $!{hghe} @{hgsv sounds|sound} less than impressed at your generosity. $!{hghe} @{hgsv keeps|keep} watching your face, frowning faintly.

    "I am glad we understand each other." Not much you can glean from Hollow Ground's mind than a hint of... cautious interest? Perhaps. "Don't take it personally, it might turn out we have more in common than you think."

  #"I don't like crowds. Here I know there's nobody else watching."

    "I don't like crowds. Here I know there's nobody else watching." You gesture to the room, adding "I took the liberty of shutting down the security system of course."

    "I don't have cameras in the house," Hollow Ground says with an air of disgust. "You're not the only one with an aversion to being watched."

    "I see." Good to know about the lack of cameras, you didn't take the time to investigate exactly what the systems were when you shit them down. It makes sense, Hollow Ground have worked hard on keeping ${hghis} existence a secret, and recordings are easy to leak. Better to have good security outside and leave the inside as private as you can. That also means that even if the system would start up for some reason, your secret would still be safe. Time to get down to business. "It turns out that disliking cameras is not the only thing we share."

  #"I wasn't sure it wouldn't be a trap. Here I'm in control."

    "I wasn't sure it wouldn't be a trap," you admit. "You can imagine how it would look from my end. Venturing into the lion's den without my armor, facing who knows what goons and villains. Here I am in control." 

    "And yet you still came to me. On my turf. One might argue this would be even more of the lion's den." Hollow Ground keeps watching you, you can nearly hear the wheels of his mind turn, trying to work out why you are here. What you are up to.

    "On my terms, though. Taking a few precautions. I've got no plans to make the mistake most new villains make and underestimate the competition."

    "And so you decided to break into my house in the middle of the night." $!{hghe} @{hgsv sounds|sound} almost impressed. "Some would call that a mistake."

    "Others would call it an opportunity. It might turn out that we have more in common than you think."

"Like what?"

*set nicechat true

*goto reasons

*label reasons

It is a good question. There are a number of things you want to talk about with Hollow Ground, the question is where do you start.

*if ((motivation = "revenge") or (motivation = "justice"))

  Like it or not, ${hghe} could be useful to your plans down the line. You've got powerful enemies, it might be smart making powerful friends.

*elseif motivation = "fate"

  The fact that ${hghe} @{hgsv reminds|remind} you of yourself feels like a sign. It can't be coincidence that you're here. That you've met. It can't.

*elseif motivation = "life"

  You've been working on reclaiming your life. $!{hghe} could be a great help there, or an equally great hindrance.

*else

  There are so many things about ${hghim} that rub you the wrong way. The smugness. The way ${hghe} @{hgsv expects|expect} everyone to bow to ${hghim}. Makes you want to punch ${hghim}. But you also need to be smart.

*if anarchist

  There are just too many unknowns here. How much does Hollow Ground truly control? @{hgsv Is|Are} ${hghe} nothing but a crime boss who doesn't care much who is in charge as long as they leave ${hghis} business alone? Or @{hgsv does|do} ${hghe} have a bigger agenda? Is Mayor Alvarez an ally, a tool, a victim or completely incidental to ${hghim}? Do Hollow Ground need to be taken out of the picture, or could ${hghe} become an ally if ${hghe} knew the truth?

  [b]@{hgsv Does|Do}[/b] ${hghe} know the truth?

  You wish you knew. You wish you could read ${hghis} mind to find out. No certainty. Only questions. It might be worth playing nice long enough to gather more information, or it might be better to make it clear that Hollow Ground should stay out of your business and go your separate ways. Maybe even make an example right here and now.

*elseif boss

  Hollow Ground can be an opportunity. You wouldn't be here talking if you weren't already wondering how to turn this to your advantage. Building an organization from the ground up takes time and effort, if you have the chance to use a previously existing network that would speed things up. You have no intention playing second fiddle to Hollow Ground forever, but working with ${hghim} for now? The things you could learn, not everyone can be this well shielded against telepathy. 

  It might be worth playing nice long enough to learn the opposition. Maybe even take it over. On the other hand, you might want to put your foot down and make it clear that Hollow Ground should stay out of your business. Maybe even make an example right here and now.

*elseif prepare_them

  Hollow Ground was not on your radar when you started your crusade. Villains were less important than the heroes, how could you trust any of them even if they might be useful? But sitting here, in ${hghis} fancy kitchen, with ${hghis} lovers sleeping peacefully a few rooms away you start to wonder. $!{hghe} @{hgsv has|have} as much to loose as anybody once the shit hits the fan. Maybe you don't need people with the will to do the right thing, maybe the fear of losing everything ${hghe} @{hgsv has|have} gained might be as powerful a motivator. 

  Could ${hghe} be an asset? Possibly. 

  On the other hand, ${hghe} @{hgsv is|are} used to sticking to the shadows, ${hghe} might just figure out that nothing would change for ${hghis} organization. Might even think ${hghe}'d prosper. You know too little about ${hghim} to know how ${hghe}'d react to the truth. It might be worth getting close to find out. On the other hand, you might want to put your foot down and make sure Hollow Grounds know you're a free agent and stick to your original plans. Maybe even make an example right here and now to make sure you're understood.

*elseif hunter

  Hollow Ground is not a threat to you. An inconvenience, yes, just like any other sprawling organization with fingers in too many pies. But a threat? No. You broke into ${hghis} house without breaking a sweat, if you wanted ${hghim} dead ${hghe} would have been. The question is what else could ${hghe} be?

  An opportunity?

  It might be nice to have an ally in the criminal underground. You doubt your plans would be anything Hollow Ground would object to. Maybe even pay you for some of the people on your long list of possible targets. Could get two birds with one stone. On the other hand, that would make you less independent. You would risk being seen as one of ${hghis}. That thought make you wonder if maybe you're not better served making an example right here, to make sure you drive the point home.

*else

  You could already have robbed Hollow Ground blind, but all that would have given you would be money and bragging rights. Hmmm. When you put it that way, maybe you should have done just that. What a score, too bad most people wouldn't even know who you stole from. Just another random rich asshole. 

  Would it be smart to to play nice? To maybe have an ally? Or at least not an enemy? Or perhaps you should put your foot down and drive home the point that you are an independent operator? Maybe even making an example right here?

*if hghelp

  And then there is Ortega. You did promise to help ${him} investigate Hollow Ground. Right now you know ${hghis} face and where ${hghe} lives. You could technically carry ${hghim} off into the night, if you had any actual proof of anything. In order to get that, you'd have to play nice for now. That way you would have ample time to decide which horse to back in that race. 

  If any.

You ponder the ${gender} in front of you. The way ${hghe}@{hgsv 's| are} waiting for a reply. Nervous. Pretending to be in control. Looking at you as if ${hghe} @{hgsv is|are} trying to solve a riddle. Who are you? Really? You can almost hear those words though ${hghis} mouth is pressed together in a thin, tense, line. 

*goto talkchoice

*label talkchoice

*fake_choice

  #I will do my best to be friendly with ${hghim}. For now.

    *if hgmind

      You can't let what just happened affect you, whatever delusions Hollow Ground has will remain ${hghis} own. That being said, you're probably best served by staying friendly for now.

    *else

      No matter what you decide to do in the future, you're convinced that you're best served by being friendly for now.

    You've got enough enemies already, there's little to be served by adding another one to your list.

    *goto friendlyhgtalk

  #I will tell ${hghim} never to mess with me or mine again.

    *if hgmind

      You can't let what just happened affect you, if

    *else

      If

    there is one thing you have learned, that is that if people think they can push you around, they will do so. Hollow Ground have already tried to do so once, you need to make sure ${hghe} never @{hgsv tries|try} something like that again. Ever.

    *goto threatenhgtalk

  *if (thief) #I will rob this place, that will show ${hghim}.

    *if hgmind

      You can't let what just happened affect you,

    Hollow Ground needs to be taught a lesson. If you want to break in somewhere and steal something, there is nothing ${hghe} can do to stop you. 

    *goto kitchenrobstart

  *if (not(thief)) #I will make an example why I should not be crossed.

    *if hgmind

      You can't let what just happened affect you,

    Hollow Ground needs to be taught a lesson. $!{hghe} @{hgsv thinks|think} ${hghe}@{hgsv 's| are} in control here. Nothing could be more wrong. It's time for payback.

    *goto paybackhg

  *if (not(hgmind)) #I will risk trying to break ${hghis} mind-shields to learn more.

    Hollow Ground's mind feels strange, at least the surface layers you can't help but brush against. Shielded, yes. You can't read any deeper thoughts, and what reactions leak through are as much projected through ${hghis} face as anything else. Is it training? Drugs? Some weird mental condition? Powers? Too many unknowns. Curiosity might kick the cat's ass, but you need to know.

    *goto hgminddive

*label hgminddive

"Do you really need to ask what we have in common?" you say, your words more distraction than truth as you try to judge your point of entry. "It's on the tip of your tongue as well, I'm willing to bet."

Hollow Ground's mind leap into action at your words, as if ${hghe} already had suspected what you were going to say. Your resemblance, to strange and striking to be pure chance. At least it seems that ${hghe} @{hgsv is|are} convinced that is the case.

Interesting. That might be a way in.

*set hgmind true

*if ((subterfuge >= 80) or (arrogance >= 70))

  You gently brush your fingers over ${hghis} mind, urging that curiosity to the surface. The reflective pond goes strangely clear, as you tempt ${hghim} with answers, giving you an opening to slip inside. 

  A smooth entry, a perfect dive leaving no ripples in this frozen moment.

  *page_break Contact!

  There are dangers everywhere around you, but you don't let them catch you unawares. It's a beautiful mindscape, a coral reef filled with life and color, hidden dangers lurking in crevasses, the ever-present sea anemones trailing their tendrils everywhere. A less talented telepath would be tangled and risk triggering a memory, but you're a master of your craft.

  Familiarity can be a useful shield. You can brush against thoughts and memories, picking up details. There's already enough of a rapport you can use for groundwork. Similarities, not just in looks but in…demeanor?

  Very carefully, you reach into one of the darker crevasses, a crack going deep, as if an earthquake cracked the mind down to the core. There are things there, old memories, slippery and cold and out of the sun.

  [i]"Put your hand in that crack,"

  *line_break

  [i]"and you won't get it back…."

  Singing? A memory?

  [i]The aquarium is as tall as you are, filled with all the brightness of the tropical sea. Fish glitter past like confetti, too small to pick out, but together they're strong. Your breath is misting the glass, but you're entranced, it's the best day of your life, you didn't think…

  Wait. Your life?

  [i]A reflection in the glass, your face but far younger than you've ever been, eyes meeting yours and

  *if trans

    [i]it's wrong,

  *if not(trans) 

    [i]too young,

  [i]too innocent, the smile, the chubby cheeks, and there's a hand on your head, a fond ruffle and a whisper in your ear.

  [i]"…that's a moray."

  A memory. Of course. It stinks of Hollow Ground. A fond memory? Intense enough to form ${hghis} mindscape? Looks like it.

  You yank your hand out just before the moray strikes, two sets of teeth missing your fingers, and you bare your teeth in an echoing growl. It's dangerous this deep, you can feel yourself sinking into memories of your own, [i]of different tanks, not filled with saltwater but amniotic fluid, trapped, the faces glaring at you covered with surgical masks, tapping the glass, and you twitch, echoes amplified and you can't get out and do you even know what's out? Do you know anything?

  *page_break $!{swear}!

  [i]Too loud. Everything echoes, their thoughts so loud, and none of them concerned with you. You. There is no you. Just a body. A potential. Nobody bothers to name the fish in the tank. If you did, you'd have to grieve when they started floating belly up.

  Lies. You named them.

  [i]You named yourself.

  Floating belly up. How did you lose yourself in here? You went too deep, you need to breathe, but everything you touch gives way, climbing kelp and looking for the sun.

  [i]~I got you.~

  [i]Dragged back, pulled out, pushed behind. Protected. The ghost of a memory. 

  "Fuck." Hollow Ground coughs, clinging to the table as if it was the only thing keeping ${hghim} upright. You're back in the room with blood in your mouth and salt on your cheeks. "What the hell was that?"

  *set hg_friendship %+ 20

  *set hgknown_telepath true

  *set protected true

  *set force %+ 10

  *if gate >= 1

    *set gate - 1

  *else

    *set scar - 20

*else

  You gently brush your fingers over the surface of ${hghis} mind, bringing feelings to life. Not just curiosity, but regret? Pain? Probing deeper, you reach into the dark and something snaps at your fingers, coiled and thick like a cable, caustic yellow not gentle red.

  Pain, real this time. Your hand hurts, but then something grabs it, pulling you inside.

  *page_break Deeper.

  [i]The aquarium is as tall as you are, filled with all the brightness of the tropical sea. Fish glitter past like confetti, too small to pick out, but together they're strong. Your breath is misting the glass, but you're entranced, it's the best day of your life, you didn't think…

  [i]Wait. Your life? No.

  [i]A reflection in the glass, far younger than you ever were, eyes meeting yours and

  *if trans

    [i]it's wrong,

  *else

    [i]too young,

  [i]too innocent, the smile, the chubby cheeks and there's a hand on your head, a fond ruffle and

  "Get…out," [i]distant words, shields closing like jaws upon jaws, forcing you to withdraw or get swallowed. Big and coiled and red and spotted, a nightmare driving you back to a surface only half remembered.

  "Fuck." Hollow Ground coughs, ${hghis} words now, you know that. ${hghe} @{hgsv is|are} clinging to the table as if it was the only thing keeping ${hghim} upright. You're back in the room with blood in your mouth and salt on your cheeks. "What the hell was that?"

  *set hgknown_telepath true

You wish you had an answer, but you're as shaken as ${hghe} @{hgsv is|are}. It happened so fast the Rat-King didn't have time to interfere, busy with keeping Nocturne and Jake asleep as they were. You can feel their worry now, and assures them that you are fine.

You're not sure if they believe you.

*fake_choice

  #"Our minds got entangled," I evade. "You're a boost, aren't you?"

    "Our minds got entangled," you evade, using a neutral phrasing to minimize your own blame. "You're a boost, aren't you? I think our powers interacted with each other."

    *if arrogance <= 30

      "I felt it." Hollow Ground rubs ${hghis} face, as if trying to wake up. "I felt... you."

      "I feel queasy," you admit, because you feel like you keep wanting to reach out, to get entangled, find out what happened and get some answers. "This has never happened before." That is true, you've had some adverse reactions to reading minds, but in those cases you've been treated as hostile. This felt more like being pulled in, being forcefully made a part of something.

      "No, it hasn't." ${hghe} @{hgsv is|are} as shaken as you are. "You're a telepath, but that shouldn't affect... that shouldn't..." ${hghe} @{hgsv keeps|keep} looking at you. "Did you do this?"

      "No?" Your confusion is honest, because you get the feeling ${hghe} @{hgsv is|are} talking about more than just the intrusion.

      "Oh God." $!{hghis} words are quiet, hardly audible. "Is... is it really you?" The words fall out, flat on the table between you, coins not heads or tails but on the edge, spinning freely. 

      *goto mindtalkcont

    *else

      "That's one way of putting it." Hollow Ground sounds less than amused, but also too shaken by what just happened to argue. "You were trying to read my thoughts."

      "It's a reflex," you lie. "You were the one that pulled me in."

      "Like hell I was." It sounds like ${hghe} @{hgsv is|are} not buying it, you can feel the anger rising like steam. Tempered by... familiarity?

      "What do you want? An epology?" You still try to make sense of what just happened. What you saw.

      "You never apologized once in your life, don't tell me you're going to start now." The words are out, flat on the table between you, coins not heads or tails but on the edge, spinning freely. 

      *goto mindtalkcont

  #"None of your business," I snap defensively.

    "None of your business," you snap, going on the defense though you have no idea what is attacking you. What was that? In  mind? You can still feel the memory cling to you, as if it was trying to worm its way under your skin like a parasite. 

    "It is my damn business," Hollow Ground swears, his voice lowered to an angry hiss. "You tried to get into my mind," ${hghe} @{hgsv shakes|shake} ${hghis} head. "In [b]my[/b] mind!"

    "So what?" Your tone matches ${hghis}, because you have never once backed down from an argument. "Are you seriously surprised?"

    "I shouldn't be, you always were a little shit." The words are out, flat on the table between you, coins not heads or tails but on the edge, spinning freely. 

    *goto mindtalkcont

  #"You tell me," I whisper. "Why was [b]I[/b] there?"

    "You tell me," you whisper, as if afraid to speak out loud. "Why was [b]I[/b] there?" Inside ${hghis} mind, a reflection that never was.

    "Shut up and let me think." Hollow Ground sounds as rattled as you feel, looking at you as if ${hghe} had seen a ghost. "You saw it too?"

    "The aquarium. What the hell that was." You can still feel the memory cling to you, as if it was trying to worm its way under your skin like a parasite. "I don't understand."

    "Neither do I," ${hghe} @{hgsv admits|admit}. "I haven't thought about that in years, not since you..." ${hghe} breaks off suddenly, staring at you. The words lie still on the table between you, flipped coins landing sideways. Neither head nor tail.

    *goto mindtalkcont

  *selectable_if (protected) #"You saved me," I gasp, focusing on that. "Why?"

    "You saved me," you gasp, trying to swallow the taste of blood and drowning. "Why would you do that?" $!{hghe} must have known what you were trying to do. You're not sure if Hollow Ground is a telepath, but there is some form of mental powers at play here, that you could feel. Something...

    "Hell if I know," ${hghe} @{hgsv lies|lie} and you know that know. Can taste the lie, not because your minds are entangled but because you can see it in ${hghis} eyes.

    "Liar," you retort, wiping your mouth. 

    "You tried to get into my head," ${hghe} @{hgsv snaps|snap} in return. "In [b]my[/b] head!"

    "And you're surprised about that?" Your tone matches ${hghis}, because there is something so close to slipping out if only you can make ${hghim} mad enough to let it slip.

    "I shouldn't be, you always were a little shit." The words are out, flat on the table between you, coins not heads or tails but on the edge, spinning freely. 

    *goto mindtalkcont

*label mindtalkcont

"What are you talking about?" Hollow Ground knows you. No. ${hghe} [i]@{hgsv thinks|think}[/i] ${hghe} @{hgsv knows|know} you. Your face. Older but familiar. The memory still hangs on your lips.

"You don't know?" You can sense the disbelief, ${hghis} eyes narrowing. "Fuck. Of course. That makes sense. Too much sense."

"No it doesn't," you protest.

"Do you remember anything?" Hollow Ground leans forward, too insistent now, almost reaching out to touch. You lean back, putting space between you despite the protection of your armor.

"About what?" Why are you the one being interrogated? What did you see in there? What did you feel?

"Your childhood." The words land heavily and you almost laugh. As if you were ever a child.

And yet that memory keeps rising to the surface of your mind. $!{hghis} mind. $!{hghis} shields are fraying now, too focused on you to care about ${hghim}self. What is it that you're picking up?

@{hgsv Does|Do} they really think you're...?

That you're... someone ${hghe} used to know? Related to ${hghim} even?

*fake_choice

  #"Our memories got entangled. It's nothing more than that."

    "Our memories got entangled," you say, unwilling to indulge whatever fantasy the kingpin of Los Diablos is entertaining. "It's nothing more than that. Give it a few days and everything will fade away."

    "You don't understand," Hollow Ground pleads, and you can feel the need in ${hghis} voice. "Just answer the question, please."

    "It's irrelevant." You force yourself to put your shields back up. "And it is definitelly not why I came here."

    "Why did you come then?" You can hear how suspicious ${hghe} @{hgsv sounds|sound}, unwilling to let this go, yet with no avenue to force you to answer.    

    *goto talkchoice

  #"You... had a sibling," I say, uncertainly. "Is that...?"

    "You... had a sibling," I say, uncertainly. "Is that...?"

    "Yes. Yes I did." Hollow Ground looks directly at you, eyes widening in surprise. "I thought I had lost them years ago. I thought they were dead."

    "Some people don't stay dead forever." You didn't, you should have, again and again and yet you kept coming back.

    "Could it be...?" A pause, ${hghis} fingers tapping nervously against the table. "You would have been in your early teens. There was an... attack. They called it an accident, but nobody was fooled. You had been arrested, they say you suffered an overdose. They never let us claim the body, so I always figured it was police brutality. Didn't want us to see the evidence. I never thought there was a chance that you were alive?"

  #"No," I say, which is technically not a lie. "Why?"

    "No," you say, which is technically not a lie. No childhood unless you count being newly decanted, fumbling your way through the world before your memory implant. "Why?"

    "Because you remind me of someone." Hollow Ground looks directly at you, eyes narrowing. "Someone who I thought I had lost long ago. Someone who should be dead."

    "Some people don't stay dead forever," you joke with your grimmest smile, but ${hghe} @{hgsv takes|take} it the wrong way, eagerly leaning forward.

    "Could it be...?" A pause, ${hghis} fingers tapping nervously against the table. "You would have been in your early teens. There was an... attack. They called it an accident, but nobody was fooled. You had been arrested, they say you suffered an overdose. They never let us claim the body, so I always figured it was police brutality. Didn't want us to see the evidence. I never thought there was a chance that you were alive?"

  #"None of your business," I say harshly. 

    "None of your business," you say harshly, unwilling to indulge whatever fantasy the kingpin of Los Diablos is entertaining. "We don't know each other like that."

    "Are you sure?" Hollow Ground pleads, and you can feel the need in ${hghis} voice. "Just answer the goddamn question."

    "No.It's irrelevant." You force yourself to put your shields back up. "And it has nothing to do with why I came here."

    "Get on with it then Why are you here?" You can hear how suspicious ${hghe} @{hgsv sounds|sound}, unwilling to let this go, yet with no avenue to force you to answer.    

    *goto talkchoice

You can feel the hope radiating from ${hghim}. An old wound, reopened. Someone who loved their

*if afab

  little sister

*elseif amab

  little brother

*else

  younger sibling

and is now hoping that ${hghe} had been wrong all along. That there is a chance there had been no death. No body. Just someone disappeared into the system for whatever nefarious purposes. Someone who might be sitting at the table across from ${hghim}. Maybe.

Hope. The most powerful and addictive of drugs.

*if (((amab) and (gender = "woman")) or ((afab) and (gender = "man")))

  You know in your heart that it is wrong. Not just because you are a Re-Gene and never was a child. But because the child you saw in ${hghis} mind had been a @{afab little girl.|little boy.} And you never would have been. Not back then. 

*else

  Too bad that ${hghe} @{hgsv is|are} wrong. Dead wrong. You're not even human, and here ${hghe} @{hgsv is|are} trying to convince you that you are family.  

Your face twitch in a pained grimace, and you look down.

"I'm sorry." Hollow Ground speaks first, as if ${hghe}@{hgsv 's| are} suddenly aware how intensely strange this situation is. "I didn't mean to..."

*fake_choice

  #"... to do what?" I ask, mouth filled with pain. "Upset me?"

    "...to do what?" you ask, mouth filled with pain. Did you bite yourself during the intrusion? You might have, you've been tasting blood for a while now. "Upset me?"

    "When you put it like that..." Hollow Ground can't stop the laugh as ${hghe} @{hgsv pulls|pull} the robe tighter around ${hghis} shoulders. "You did break into my hoise. I shouldn't care whether I upset you or not."

    "You're right." You let out a sigh, focusing on the pain and blood. "I did come here for a reason, everything else is irrelevant for now."

    "We don't have to talk about what just happened yet." $!{hghe} sounds eager to let it go, as if ${hghe} @{hgsv doesn't|don't} know how to deal with this possibility yet either. "Why did you come here?"

    *set hgsib? true

    *goto talkchoice

  #"... to presume that you know me?" How dare ${hghe}?

    "... to presume that you know me?" How dare ${hghe}, trying make your story into ${hghis} own. "You don't. Whatever you think is worth nothing. You hear that? Nothing." You hiss the last with enough force to make ${hghim} lean back and pull the robe tighter around ${hghim}self.

    "Of course." Hollow Ground's voice is surprisingly agreeable, eager to calm your temper. "Whatever that was just took me off guard. Nothing more." @{hgsv Is|Are} ${hghe} trying to placate you? Probably. But that doesn't change the fact that this is you getting sidetracked.

    "Don't bring it up again." You let out a sigh, focusing on the matter at hand. "I came here for a reason, not to sit here discussing family memories."

    "Of course." $!{hghe} sounds eager to let it go, as if ${hghe} @{hgsv doesn't|don't} know how to deal with this possibility yet either. "So tell me, what brings you here?"

    *set hgsib? true

    *goto talkchoice

  #"Never mind," I sigh. I need to get back on track. "Let's move on."

    "Never mind," you sigh. You need to get back on track, whatever is happening here is a distraction from your real goal. "Let's move on."

    "You can't just tell me to ignore what's right in front of me." Hollow Ground can't stop the frown ${hghe} @{hgsv pulls|pull} the robe tighter around ${hghis} shoulders.

    "I can and I will." You let out a sigh, wondering if ${hghe} @{hgsv realizes|realize} that ${hghe} @{hgsv is|are} not the one in control here. "We're moving on."

    "Of course, we don't have to talk about this yet."  @{hgsv Is|Are} ${hghe} trying to placate you? Probably. "So why did you come here?"

    *set hgsib? true

    *goto talkchoice

*label friendlyhgtalk

*label threatenhgtalk

*label kitchenrobstart

*label paybackhg