Stagnation (Patreon)

Well, not a full puppetstuck demo yet, but we are getting closer. 16 400 words of path 2.3, the puppet arrested by Steel after helping to free the broken MC. Would have been more, but we have a thunderstorm so this is it. I want it up tonight.

As always, it is not complete, missing choices, variants, stat additions and lots of stuff. Still, a peek behind the scene to see what is going on if you don't mind spoilers. 

....

*comment 3_ 2 and 3_3 previously broken bones.

*comment 2_3 arrested by steel. Main path.

*if gender = puppet_gender

  *set samegender true

*if voluntaryreveal

  *set guiltymc true

*elseif notthevillain

  *set innocentmc true

*else

  *if hghelp

    *set innocentmc true

  *elseif ((wounded) or (auctioncaptured))

    *if oc >= 50

      *set guiltymc true

    *else

      *set innocentmc true

  *else

    *if oc >= 60

      *set guiltymc true

    *else

      *set innocentmc true

*comment if the impostor villain is innocent or guilty. add argent and steel variables later

The air smells stale. Stagnant. Breathe in. Hold it. Breathe out. It smells like you, though you know there are vents here. They just don't work very well, the stillness of your cell is oppressive. It clings to you. Around you. Inside your lungs. No escape. It's technically not jail. You know that. You’re still in Los Diablos, under arrest, instead of having been shipped off to work for free in some secure factory jail elsewhere. A holding facility. Such a pleasantly neutral term for suspended animation. Not that you're unfamiliar to that, you spent the worst part of your life on the Farm, subject to a similar mind-numbing routine and boredom.

*if character_2_3

  But it’s different this time.

  This isn't even your body.

  Not your hands when you do push-ups. Not your lungs when you're out of breath after working out on the minimal area allotted to you, a narrow cot, a stinking toilet, window with a hint of daylight, too high up to look out. No bars, just bulletproof glass. Can't even use the ledge to do pull-ups. Its only use is to mark the path of the sun as yet another day pass.

*else

  Broken. Body hurting to the point where you can't stand it anymore.

  You should rest. You know that.

  Instead, you do your best to regain your strength. You're out of the casts, but you've lost muscle-tone and mobility. They still roll out the wheelchair when taking you places. Giving you crutches might be giving you a weapon, and it's easier to handcuff you when you sit down. Between the stinking toilet and the narrow cot there's not much place to work out, but it is enough for you to painstakingly teach yourself to stand. Lift your legs. Embrace the pain. Move. Again. And again. Lay on the cot and stare at the narrow window near the ceiling when you're exhausted. Watch the spot of sunshine move across the cell.

Keeping track of time is important at this point, so you do. Little marks on a wall, vandalism in the name of sanity. One day the reverse might be true, forgetting the passage of time is the only way to stay sane. Living for the day. You’re not there yet. Hopefully you’ll never be.

*if character_2_3

  *goto wholebody

*else

  *goto healingbody

*label wholebody

Your only consolation is that as far as you know, your body is safe. Trust. You sacrificed yourself to make sure of that. Once your body has recovered enough you should be able to slip back inside ${chis} head. Right? This is only temporary.

Temporary is taking an awful long time, though. You've been stuck here for weeks. A month and a half. Marshal Steel has come to interrogate you a few times, a change of pace from the LDPD goons.

*if nointerrogation

  He's still sore about you attacking him. Hurt pride. You take some solace in that, in being able to surprise him. He's added up the clues, of course. You were there to distract and delay him while your accomplice got ${name} ${surname} out. He's been trying to get you to give you any names, any information you have on ${surname}'s whereabouts.

  *fake_choice

    #I've said nothing.

      You've given the Marshal nothing, of course. Keep your mouth shut and rest easy knowing that @{boss Pelayo|${hench_name}} got your body out of there. Hopefully, with time you will be able to regain control.

      *set stonewalling true

    #I confessed to helping, and let him know ${name} was safe.

      The Marshal already knew you were involved. Your attack made that obvious, so you had no qualms to admitting to your part. Of course what he really was digging for was why.

      *if knowssteelsuspects

        You know he suspects ${name} ${surname} of being ${villain_name}, but he has no proof. And really, you're not about to give him that.

      *else

        You're not about to tell him that.

      What you have told him is that ${name} is safe with friends, and that he should stop looking. If you can do something to defuse the heat, that's good. You don't need to be found, you need time to heal so you can regain control.

*else

  *if stonewalling

    Not that it has helped him any. You've kept your mouth shut this long, you're not exactly about to start talking now. You know @{boss Pelayo|${hench_name}} got your body out, at this point all you can do is to wait for it to heal enough for you to regain control.

  *else

    The fact that you told him ${name} was safe with friends has defused some of the heat of his questions. Of course that has also meant that he knows you're involved, and has valuable information. A person of interest. He's not about to let you go, so at this point you are stalling for time so your body can heal enough for you to regain control.

  *page_break $!{swear}.

*if ((puppetortega_relationship = "none") or ((puppetortega_relationship = "workout friend"))

  *set puppetortega_relationship "bad"

*if ((puppetortega_relationship = "friend and confidante") or ((puppetortega_relationship = "eternally flirting"))

  *if stonewalling

    *set puppetortega_relationship "bad"

  *else

    *set puppetortega_relationship "on shaky ground"

*if puppetortega_relationship = "semioffically dating"

  *set puppetortega_relationship "on shaky ground"

It's been too long. Even with a bad concussion, you should have recovered. How badly were you hurt? You don't know, and that's terrifying. This can't be permanent, of course not, but what if you're temporarily stuck? Your current theory is that the shock of the crash, combined with your injuries, led to this. Maybe at this point distance is the issue. This body is not telepathic, and if the reflexive recall mechanism that boots you back when falling asleep or unconscious has been broken, maybe you need physical contact? Proximity. You needed that at the start with your puppet as well, touching ${phis} skin to slide into it. That's why you had your apartments so close to each other, despite the risk. It took you months to be able to do it without touch, from one apartment to the other. Only practice made distance a non-issue, your puppet accessible across town without issue.

That's the explanation that makes sense. That gives you hope. A plan. Unfortunately that plan must include getting out of here, and from the look of things, that's not happening any time soon. You're more than stuck, you're trapped.

Trapped in the no-man's land between suspicion and sentencing. You can't do anything but wait for a chance while you switch between working out and staring blankly at the wall. And while you wait, you need to suffer through interview after interview staring at the table in front of you. Calculate your options. Play the doll for real. Be mute. Uncooperative. It's not like your publicly appointed lawyer has shown much interest in helping you, a perfunctory gesture, pretending you have rights when

*if puppet_gender = "woman"

  the creep does little but stare at your breasts as you talk.

*else

  the useless asshole does little but yawn himself through your talks.

No help there. Maybe that's the point, to remind you that you have no allies left. Still, your meetings provide variation if nothing else, a refuge from the self-inflicted hell of you thoughts. Your doubts. Your regrets.

*goto forgetnot

*label healingbody

*comment write later

*comment A month and a half. Marshal Steel has come to interrogate you a few times, a change of pace from the LDPD goons. He's a temptation. Knows too much. Might know what you need to know. Maybe. $!{swear}. You want to ask Steel if ${name} ${surname} is safe. But you can't. Nobody knows ${che} is ${villain_name}. Nobody can know. And so you can't dig for information, no matter how cleverly disguised your efforts might be. Steel is not stupid, and giving facts away for free would mean you were. That's why you're still here. On hold. Because the Rangers don't know what you know and they are desperate to find out. An admission as good as any that ${name} is still missing.

*goto forgetnot

*label forgetnot

*fake_choice

  #I messed up, bad. I need to do better.

    Getting captured wasn't your worst mistake. That's what this body is for. Plausible deniability, a way to make sure your goals are accomplished no matter the price you need to pay. Replaceable. No, your mistake was agreeing to meet up with Hollow Ground. Too much of a risk, especially in a club like that. Too many minds to keep things straight, even disregarding Ortega's curiosity. You should have been careful. Gone in this body. Made some introductions.

    *if daring >= 70

      You hate to admit it, but not all risks are worth taking.

    *elseif arrogance >= 70

      You hate to admit it, but you're not invincible.

    *else

      That would have saved you a world of pain.

  #What if I can't I get back to my body? Ever?

    This has never happened before. Being locked inside your puppet. Remaining there even though you fall asleep. What if your theory of why you can't get back to your body is wrong? What if you get out, touch your face and still there's nothing? What if your comatose body will just lie there, forever out of your reach? Thoughts like that terrifies you enough to hyperventilate, biting your hand until the pain brings you back.

    Did something else break in the crash besides bones? Brain damage? Is this some sort of healing response? Like pain forcing you not to walk on an injured foot so it has time to heal? Is it some instinct inside your body that is keeping your mind at bay until your brain has time enough to heal? Will it? Can it?

    You hope so. The alternative is too terrible to consider.

  #I feel like I am losing myself.

    Who are you even? Being stuck in this body has unmoored you, removed foundations you didn't even know you needed. Your telepathy. Your Re-Gene nature. What if this is who you are now? What if everything else was a dream you were just waking up from? Too impossible to be real. Too painful to want back.

    You keep scratching your arms, as if looking for tattoos under your skin. Only red marks now, no blood, but irritation. Itching. Not even your reactions feel right, or maybe the problem is that they do. Feel natural. As if this is who you always were. Nothing else.

    If you lost yourself in here, would anybody ever know?

Being trapped inside your puppet for this long has made you realize one thing for sure. You're seen as a criminal here. None of the guards care whether you live or die, except perhaps to the point it might make their work more complicated. A prisoner. A nobody. And yet... you're human.

They despise you as a human. You annoy them as an individual. They ignore you as a pain in the ass. You're there. Real. There is nothing of the detached blankness of the farm, where you might as well be a lab animal stuck in a cage, no, because you know there were people who cared about the rats even though they shouldn't.

Too dangerous to care about the Re-Genes. You weren't a lab animal, you were a sample stored in the fridge. A petri-dish of value only for whatever experiment they were running that day. You were nothing. A blank slate with an unnervingly human face. Not blue. Look away. Ignore.

*if motivation = "anger"

  Anger is better. The guards affirm your existence with every push and snarl and insult. You feel more grounded than you have in years, trapped in one spot, in one head, no thoughts, gut roiling with fury.

  And yet you can't [b]do[/b] anything with it.

*elseif motivation = "justice"

  If you ever had doubts about your disdain of the legitimacy of the Los Diablos justice system, you have lost them now. This is where people are kept before being brought to trial. Suspects, not criminals. Innocent until proven guilty and all that.

  And yet the guards treat you all like scum.

*elseif motivation = "fate"

  And now you're here. Ignored in a different way, as if it was an inconvenience to feed you three times a day and lead you to your next interrogation. You should be angry. You should be frustrated. And yet it is all so familiar. As if this was where you were meant to be. As if you're waiting for something. For someone.

  A sign will come, of that you are sure.

*else

  Was that better? Is this worse? Never having anything compared to having lost it all? You wish you knew. You wish you had an answer. Not that it matters. Not really. You'll take it back. Everything and more. This is a temporary setback, another hurdle you need to clear.

  By this point, you're a very good jumper.

You let out a breath and hold it. Counts for as long as you can before you turn dizzy. Longer than when you first arrived here. A different kind of training. Oxygen. An annoying necessity.

*if precognition >= 30

  [i]This too, is important. Hold your breath and go towards the light.[/i] You shake your head to dispel the vertigo. This cell does strange things to you, but you're used to that. Still not as bad as the Farm. Focus on what you can.

Bodily functions. Pain. Sweat. The feeling of concrete under your fingertips. Grounding.

Your body. Not your body.

*if samegender

  *if trans

    A real ${puppet_gender}. Human.

  *else

    Human.

*else

  *if nb

    Human.

  *elseif trans

    $!{puppet_gender}. Like they designated you.

  *else

    A ${puppet_gender}. Unlike you.

*if ((samegender) and (genderquestion))

  Lately, you felt like it chafed, being seen as a ${gender}. After spending this much time as your puppet, eating, living, breathing the ${sex} experience you've come to a conclusion...

  *fake_choice

    #Being a ${gender} wasn't the issue, being a Re-Gene was.

      You thought you didn't want to be a ${gender}. But, being immersed like this, in another body with the same gender have shown you that your issues lay elsewhere.

      In your lack of humanity.

      You've never had a choice not to be the outsider, to be a pale imitation of what you are living now. That's what your issues were. Not in whether people saw you as a ${gender} or not.

      *set genderquestion false

    #I really don't want to be a ${gender}.

      You always wondered if it was a reaction to being a Re-Gene. If maybe what you weren't longing for was the easy acceptance of humanity. But, being trapped in a human body for this long has proven that's not the case at all. This body is handsome, fit, desirable and human. And yet you want to crawl out of your own skin as people keep treating you as something you're not.

      $!{sex}. The Farm designated you as that, but right now you want to be anything but.

      *set genderdoubts true

    #I don't know. I'm still confused.

      You really don't know. There's too many things mixing together, humanity, gender, attractiveness. You love this body. You hate this body. You want your own body back. How are you supposed to know who you are? What you feel? You've had too much time to think, trapped here, but none of your thoughts makes sense.

      You wish you had someone to talk to.

    #No time to think about myself right now. Only the mission.

      You've got bigger issues right now than whether people see you as a ${gender} or not. Really. You need your proper body back so you can get on with your work. Feelings are irrelevant. Unprofessional.

      So you push them away, your comfort is not what's important right now.

*elseif genderquestion

  A ${puppet_gender}. You roll that thought around in your mouth for a moment, almost speaking the words out loud to the concrete wall like a mad${puppet_gender}. It shouldn't matter, but it does. Somehow. You've never immersed yourself this deeply in your puppet body before. Not just masquerading. Living. Breathing. Day and night. Not on your terms. With other's eyes on you.

  It's made you come to a conclusion.

  *fake_choice

    *if (not(nb)) #Being a ${gender} wasn't the cause of my discomfort.

      You thought you didn't want to be a ${gender}. But, being immersed like this, in the body of a real ${puppet_gender} have shown you that your issues lay elsewhere.

      Not in your body. Or your presentation. Maybe in your lack of humanity? Maybe in how you always felt like an impostor, pretending to be something you were not?

      You're not sure. Maybe it's simply that you don't like yourself very much.

      *set genderquestion false

    *if (nb) #Gender really isn't for me.

      Being immersed like this, in the body of a ${puppet_gender} have shown you that you were right all along. Gender isn't really for you, the binary is a trap you don't want to be a part of. You acted like a ${puppet_gender} in this body because it was simpler to play up the act. Be something people could slot into a box.

      Be the ${puppet_gender} of people's imagination. A useful act. But, in the end, just an act. Being trapped in here proves it.

      *set genderquestion false

    #Being a ${puppet_gender} feels more natural than ever.

      You always wondered if your unease with your body was a reaction to being a Re-Gene. If maybe what you weren't longing for was the easy acceptance of humanity. But, being trapped in a human body for this long has proven that's not the case at all. You're unwashed, dressed in an ugly prison jumpsuit, and are lacking all the things you used to do to make this body desirable. For others, and for yourself. And yet, it feels more natural than your own.

      The guards treat you like garbage, sure, but they treat you like a ${puppet_gender}. And that matters more than you ever thought it would.

      *set genderdoubts true

    #I don't know. I'm still confused.

      You really don't know. There's too many things mixing together, humanity, gender, attractiveness. You love this body. You hate this body. You want your own body back. How are you supposed to know who you are? What you feel? You've had too much time to think, trapped here, but none of your thoughts makes sense.

      You wish you had someone to talk to.

    #No time to think about myself right now. Only the mission.

      You've got bigger issues right now than whether people see you as a ${gender} or a ${puppet_gender}. Really. You need your proper body back so you can get on with your work. Feelings are irrelevant. Unprofessional.

      So you push them away, your comfort is not what's important right now.

*elseif ((samegender) or (nb))

  It feels...

  *fake_choice

    #Strange. Like I will be found out at any moment.

      Human.

      *if trans

        $!{puppet_gender}.

      This body is that. And now so are you? You sleep, eat and drink the human experience, strip down naked for showers, and everyone treats you as if you were what you look like.

      So why do you still feel like an impostor? As if you'd accidentally scrub too hard and reveal tattoos underneath? Is this what you would feel like if you ever managed to magically remove the tattoos on your own body?

      *if trans

        Remold yourself to be who you are?

      Would you still jump at shadows? Dread your own reflection? How deep did they scar you?

      The answer is disconcerting enough to make you avoid it.

    #Right. I need this. I need this so badly.

      Human.

      *if trans

        $!{puppet_gender}.

      This body is that. And now so are you. You sleep, eat and drink the human experience, strip down naked for showers, and everyone treats you as if you were what you look like. This place is a pit, but it is also the most deeply affirming experience you've ever had. A proof of concept. A blueprint for what it would look like to be human.

      *if trans

        A ${puppet_gender} down to the last details.

      You want it. You need it. So badly.

    #Wrong. I can't forget that I am a Re-Gene.

      Human. This body is that. You sleep, eat and drink the human experience, strip down naked for showers, and everyone treats you as if you were what you look like.

      And yet you can't forget that no matter how badly they treat you, they still treat you as a human. And you're not. You're a Re-Gene. A tool. Not even cattle. You can't forget that. This body isn't an escape. It's a temptation.

      It's a trap.

*elseif trans

  It feels...

  *fake_choice

    #Strange. Like I will be found out at any moment.

      Human. Something you never was. $!{puppet_gender}. Something you left behind. This body is both, and now so are you. You sleep, eat and drink the human experience, strip down naked for showers, and everyone treats you as if you were what you look like.

      So why do you still feel like an impostor? As if you'd accidentally scrub too hard and reveal tattoos underneath? Is this what you would feel like if you ever managed to magically remove the tattoos on your own body? Remake yourself as the ${gender} you are?

      Would you still jump at shadows? Dread your own reflection? How deep did they scar you?

      The answer is disconcerting enough to make you avoid it.

    #Horrible. I'm not a ${puppet_gender}, this is a nightmare.

      You're not a ${puppet_gender}. You've spent too many years remaking yourself to slide back into that pit, and yet here you are. Drowning in people's looks, the way they treat you, talk about you, looks at you. Human, sure, better than a Re-Gene but also so much more gendered. You're an impostor here, not just pretending to be a human, but forced into a role you had left behind.

      This is a nightmare. You need to wake up.

    #Wrong. I can't forget that I am a Re-Gene.

      A ${puppet_gender}. Bad enough, but you can deal. You've lived that nightmare for years, but this is new. This is worse. Human. This body. You sleep, eat and drink the human experience, strip down naked for showers, and everyone treats you as if you were what you look like.

      A criminal, sure. Contemptible, yes. But still one of them. Human. And you're not. You're a Re-Gene. A tool. Not even cattle. You can't forget that. This body isn't an escape. It's a torture device.

      It's a trap.

*else

  It feels...

  *fake_choice

    #Nervous. Like I will be found out at any moment.

      Human. This body is that. And now so are you? You sleep, eat and drink the human experience, strip down naked for showers, and everyone treats you as if you were what you look like.

      So why do you still feel like an impostor? As if you'd accidentally scrub too hard and reveal tattoos underneath? Is this what you would feel like if you ever managed to magically remove the tattoos on your own body? Would you still jump at shadows? Dread your own reflection? How deep did they scar you?

      The answer is disconcerting enough to make you avoid it.

    #Being a ${puppet_gender} feels strangely comfortable.

      Human. A ${puppet_gender}. This body is that. And now so are you. You sleep, eat and drink the human experience, strip down naked for showers, and everyone treats you as if you were what you look like. It feels strangely comfortable. You've never stayed a ${puppet_gender} for this long before, it feels more and more natural as time pass.

      Is it your humanity or your ${puppet_gender}hood?

      You're not sure, but there is something precious here to be found in this otherwise disastrous situation. Something to learn about yourself. You just wish it was under better circumstances.

      *set genderquestion true

    #Wrong. I can't forget that I am a Re-Gene.

      Human. This body is that. You sleep, eat and drink the human experience, strip down naked for showers, and everyone treats you as if you were what you look like.

      And yet you can't forget that no matter how badly they treat you, they still treat you as a human. And you're not. You're a Re-Gene. A tool. Not even cattle. You can't forget that. This body isn't an escape. It's a temptation.

      It's a trap.

"${puppet_name} Doe." Your name with your government-assigned surname tacked on at the end makes you wince, but since you haven't offered them one, they went with the classic. "Prepare to be transported for questioning."

"Again?" You sigh, but assumes the position so they can enter the cell and cuff you for the walk. Are they really that afraid of you, or did the Rangers' involvement just make everyone paranoid?

*if (((steelhurt) or (steelmodhurt)) or ((steelinjured) or (shotsteel)))

  You suppose that what you did to Marshal Steel would put everyone on edge.

*elseif steelfoughtpuppet

  You suppose that Marshal Steel would have warned everyone about you.

*else

  Wouldn't want to lose the Rangers' star witness.

Cuffs. Hands and feet, not clenched tight enough to hurt, but enough that you wouldn't be able to slip out of them. Chains connecting everything, enabling you to walk, but not at more than a slow shuffle.

*fake_choice

  #Chains. I hate them.

    Chains. You hate them. They used restraints at the Farm as well, though you never rated more than soft kevlar straps. No clinking in the hallways there, no metal to interfere with scanners or similar things. The kevlar was better. Light. Quiet. Hygienic. Not so obvious.

    They want it to be obvious here. The chains are heavier than needed, the clinking adds to the ambiance. A show of force. You're a wild animal again, led by your handlers, all that's missing is a muzzle. Oh well, you haven't bit anybody this time. Yet.

    There's a time and place for everything.

  #They mean to humiliate me.

    It's not the first time you've been restrained, they used similar means at the Farm. Not chains, just soft kevlar straps. No clinking in the hallways there, no metal to interfere with scanners or similar things. The kevlar was better. Light. Quiet. Hygienic. And, just like it was there, you suspect it's not just to keep you from escaping.

    No, they want to humiliate you. Drive home the point that you are at their mercy. You move at their command, at their speed, which of course is slightly faster than what would be comfortable with the chains. They want you to stumble.

    You do your best to remain on your feet.

  #It's strangely validating.

    Being restrained is not comfortable, but it it strangely validating. It means they see you as a threat. You remember the times you were restrained back at the Farm. No chains there, just soft kevlar straps. No clinking in the hallways, no metal to interfere with scanners or similar things. The kevlar was better. Light. Quiet. Hygienic. It also meant they couldn't be sure you would obey. Even though you shouldn't understand the concept of disobedience.

    You wore that distrust as a patch of honor, even when your resistance was ground down and you went back to being the obedient Re-Gene you kept that memory close. You were capable of rebellion. Of free will. Of saying no.

    You do the same now, though this body might be weak and powerless compared to your own, they think you are dangerous enough to need chains. That means that they fear you. And that means that you are someone to be feared. You need that strength.

The shuffled walk ends, as always, at the interrogation room. Routine. What awaits you inside is not.

Who. Who awaits you inside.

Ortega. $!{swear}.

You try not to look at ${him} as you're led to the chair, and your cuffs fastened to the frame. A security measure, as if you were about to get out of the chair and slam ${him} over the head with it.

*fake_choice

  #Tempting, but foolish.

    It is a tempting thought, even if the repercussions would probably not have been worth the moment of brief satisfaction. Could you have done it even if the chair was of the normal variety? Doubtful, the chains doesn't give you enough leeway to raise your hands over your head, and you really want that to get good leverage.

    Instead you settle for a harsh glare.

  #Keeping your composure is hard enough without violence.

    You need to keep your composure, not indulge in reckless thoughts of violence. The only advantage you have so far is your temper, you've been holding up against hope and desperation both so far. You can't let a change of interrogator rattle you. You're in control here, at least of your own temper.

    So instead of moving, you smile. Calmly.

  #Breathe. Look down. Don't tear up.

    Breathe. You tell yourself that, because your lungs have cramped up. In. Out. Look down at the table until you have stared hard enough that the sting in your eyes is from effort, nothing more. You can do this. You can't afford to crack now.

    Looking up, finally, you meet his gaze head-on.

"What are you doing here?" Your voice is steady. Inflectionless.

*if character_2_3

  *goto wholeinter

*else

  *goto brokeinter

*label wholeinter

"Silly me, here I thought you should ask why I didn't come before." Ortega's face bears no marks of the crash, enough time has passed that any remaining scarring would be easily hidden by makeup. Of course ${he}'d look impeccable for a visit in jail, the clothes understated and expensive, with an official feel to them you haven't seen since ${his} Marshal days. You're surprised ${he} didn't show up here in ${his} Charge suit to make an impression. Or, worse, leave a strategic button or two open.

"Don't flatter yourself." You look away, letting your gaze train across the walls, the one-way window where you wonder if others will be watching. You doubt it, Ortega always liked ${his} privacy. "You'd have no reason to visit."

*if puppetortega_relationship = "on shaky ground"

  "Huh. So this is really masks off then, is it?" Ortega pulls ${him}self up straighter in the chair, as if ${he}'s trying to pretend that ${he} isn't wearing a mask right now. Hypocrite.

  "I thought that was the case when I was arrested." You keep your voice even. Cold.

  *if ortega_flirting_puppet

    None of the smiles you usually aim in ${his} direction. None of the heat. Both of you are cinders and coal, no diamonds, no fire. Matching each other once again.

  *else

    No warmth. Not friends. Not now.

  "I was in a hospital bed when that happened." $!{he} looks uncomfortable with your steady gaze, for once ${his} eyes does the wandering. A small victory, but you'll take it. "I didn't really have much say in that."

  "And if you hadn't been?" You try to gesture, but all you get are rattling chains. Though you suspect that proves your point even better. "Don't tell me you would have argued the Marshal into letting me go? After what happened?"

  "It is true then?" $!{his} eyes meet yours. Trying to dig deeper.

  "Oh don't give me that." Your anger breaks the surface at last. "As if you haven't gone over every shred of video evidence by now, interrogated every single staff member of the hospital. If you're just going to sit here trying to bait me into seeing you as sympathetic you might as well get the hell out of here."

*else

  "You haven't exactly been forthcoming with your answers." Ortega pulls ${him}self up straighter in the chair, trying to project an air of authority.

  "So you thought you could do better?" You can't stop the laugh, bitter and cold though it might be. "Trust me, you're not half as smooth as you think you are. I have even less to say to you than to the Marshal."

"Cold." $!{his} mouth twitches.

*fake_choice

  #"Honest," I retort.

    "Honest," you retort.

    "Really?" Ortega's mask cracks, the calm control exchanged for exasperated frustration. Another win for you. "Somehow I doubt that you even know what that word means."

    *if suspect_ortega_uses_puppet

      "Do you?" It feels good to keep control when ${he} is slipping. "Don't you think I know why you approached me by now?"

      "That's beside the point," ${he} protests. Huh. You've long suspected that Ortega's intentions with ${puppet_name} was far from innocent. "And I'm not going to be baited into an argument."

    *else

      "Do you?" You toss the accusation back at ${him}, at this point you know how shady Ortega can be. Parkfield proved it, if nothing else.

      "That's beside the point," ${he} protests, the look of guilt quickly suppressed. Huh. That hit a sore point. "And I'm not going to be baited into an argument."

    "Fine," you say, narrowing your eyes. "we can stare at each other in silence."

  #"Realistic," I say with a sigh.

    "Realistic," you say with a sigh. "I've had a lot of time to think."

    "A lot of time to repent?" Ortega tries a smile, but it doesn't reach ${his} eyes and both of you know it.

    "That would imply I have something to be sorry for." You look down at your manacled hands, shrugging. "I did what I did for reasons that are my own. That's it, you're not getting me to talk."

    "So you prefer to do what? Stare at me in silence?"

    "Why not?" You proceed to do just that, daring him to speak first.

  *selectable_if (puppetortega_relationship = "on shaky ground") #"Hurt," I say with a look of betrayal.

    "Hurt," you say with a look of betrayal.

    *if ortega_flirting_puppet

      "I thought we had something."

    *else

      "I thought we were friends."

    "You should have thought about that earlier." Ortega's mouth twitches, as if ${he}'s biting down on something sour. "Do you really think you have the moral high ground here?"

    "If you cared, I would have thought you'd at least show up to scream at me for my betrayal. The fact that you didn't..." you shrug, looking away. "That tells me that you never really saw me as more than a means to an end."

    "Did you?" $!{his} eyes meet yours. Neither of you look away.

    "Sucks not knowing, doesn't it?" Denial of knowledge is your only weapon here.

    "I'm not going to be baited into an argument."

    "Sure," you say, narrowing your eyes. "We can stare at each other in silence instead."

*if stonewalling

  *goto planfailed

*else

  *goto frenemies

*label frenemies

"Fine." Ortega shakes ${his} head, giving you this tiny victory. "I'm here to talk about ${name} ${surname}."

"You're awfully free giving out that name," you reply, trying not to flinch. You're supposed to be a secret, not someone you talk about with the LDPD listening.

"You told the Marshal that ${che} @{sv was|were} with friends. And that ${che} @{sv was|were} safer than ${che} would have been in the hospital."

"You should keep your mouth shut, people might be listening." Your voice is cold as ice, but all you get in return is a chuckle.

"No, they are not." Ortega looks too smug. "Any bugs or microphones here won't pick up anything but static."

*fake_choice

  #"I can't trust that," I say flatly.

    "I can't trust that," you say flatly. "You could be telling me anything."

    "I am telling you the truth." Ortega gives you a convincing smile.

    "You're hopeless." You grit your teeth, the name is out, nothing you can do about it but hope ${he}'s correct.

  #"How?" I haven't seen that before.

    "How?" You haven't seen that before. A new mod, or has Ortega learned to modulate ${his} powers to that extent?

    "I'm full of surprises." Ortega gives you a cocky smile.

    "Or false confidence." You glance towards the window, hoping ${he} knows what ${he}'s talking about. Your name is out there, nothing you can do about that now.

  #"That doesn't matter. You need to be careful."

    "That doesn't matter," you say with a frown. "You need to be careful."

    "Well, talk to me and I don't need to go around saying things like this." Ortega winks at you.

    "You're not exactly inspiring confidence right now." You glance towards the window, hoping ${he} knows what ${he}'s talking about. Your name is out there, nothing you can do about that.

"All I am saying is that from the sound of things we don't have to be on different sides."

*if voluntaryreveal

  That's rich coming from ${him}. You know you confessed to being ${villain_name} in the car, but you can't exactly tell ${him} that to ${his} face.

*elseif notthevillain

  $!{he} seemed fairly convinced that you were at Parkfield for innocent reasons. $!{he} might actually be serious.

*else

  Is ${he} telling the truth? Does ${he} really have no idea you're ${villain_name}?

  *if hghelp

    You did offer to help out with Hollow Ground, that would probably be explanation enough for your presence, anything else could be up to panic in the moment.

  *elseif ((wounded) or (auctioncaptured))

    You were pretty beat up. That would have helped dissuade any suspicion, whatever your reason to be there was, you paid the price for it. Nothing like being a victim to get sympathy.

  *else

    Blind loyalty can be handy.

"You are on that side of the table," you point out. "And I am the one handcuffed to a chair."

"Play ball and that might not have to be the case for much longer."

"You can't promise that. You're not the Marshal."

"That's right. I'm willing to do the things that the Marshal won't." $!{he} looks at you with a steady gaze, trying to project confidence.

*if guiltymc

  *goto guiltywhy

*else

  *goto offerwhy

*label offerwhy

"That could be a threat as well as a promise," you point out. "If you have something to say, say it."

"I wish I could, but you're right." The admission is reluctant, but it's there. "We can't talk about it here. If I can get you out of here, would you be willing to cooperate?"

*fake_choice

  #"I certainly would be more inclined to think about it."

    "I certainly would be more inclined to think about it." You avoid giving any promises, not that you'd feel bound by them, but it never pays to seem to eager. $!{he}'s the one that wants something here.

  #"Yes, but I can't guarantee I can give you what you need."

    "Yes, but I can't guarantee I can give you what you need." You make sure to sound eager but worried. Better to avoid giving any promises, not that you'd feel bound by them. $!{he}'s the one that wants something here.

  #"Guess there's only one way to find out."

    "Guess there's only one way to find out." You don't bother to hide your smirk. It never pays to seem to eager, ${he}'s the one that wants something here.

"Good." Ortega looks relieved, as if ${he} hadn't been sure you'd agree. "I need to pull some strings to arrange this, try to lay low in the meantime."

"It's not like there's much to do in here. Laying on my cot is pretty much my number one activity. I'll do my best to not move too much." You don't smile as ${he} rises, if there's still a visual of the scene, you don't want to look too friendly.

"Good. Just be patient. I'll be in touch." The nod is nearly imperceptible as Ortega gets up to leave, but there's no trace of levity as ${he} heads to the door. Look like you both have the same idea, tell the LDPD nothing was gained and everything can go back to normal.

For now.

*set jailoutmaybe true

*goto walkback

*label guiltywhy

Does ${he} mean it? Really? Could Ortega be your ticket out of here?

*fake_choice

  #"What do you want to know?" It can't hurt to ask.

    "What do you want to know?" It can't hurt to ask. It will let you know what Ortega is focused on now.

    "I need to know about ${chis} enemies." At least Ortega doesn't mention any names this time. "$!{che} won't talk to me. Something bad is coming and I need to know."

    "Why?" You remember all too well ${his} interrogations.

    "So I can protect ${him}," ${he} says, leaning forward slightly, pleading with you.

    "Regardless," you start, keeping your face under control. Protect you. Like you're the victim here. You're not the sidekick anymore. "I can't talk about that where people might be listening."

    "I might be able to work around that." Ortega rubs ${his} forehead, glancing towards the window. "But it might take a week or two."

  #"Get me out of here first, then we'll talk."

    "Get me out of here first, then we'll talk." You know better than to offer information before getting something out of it. If Ortega is serious, then ${he} can get you out of here first. "Take me into your custody or something." It would be easier to escape from one person rather than jail.

    "That's more complicated than you think." Ortega rubs ${his} forehead, glancing towards the window.

    "If you don't have the power to get something as simple as that done despite your bragging, you're useless to me." Keep your gaze hard, you've got leverage now.

    "I didn't say it couldn't be done, only that it might take a week or two."

  #"It's not safe for me to talk to you, so no."

    "It's not safe for me to talk to you, so no." You're not going to risk your own body on Ortega's judgment. Not this time.

    "Don't be a fool. We both want the same thing." Ortega looks surprised and annoyed at your refusal.

    "I told you all you need to know." You stare ${him} down, refusing to look away. Does ${he} really think you're going to spill anything with the LDPD listening? The arrogance.

    "You don't understand." $!{he} looks down at ${his} hands, then back at you. There's a tension there that's not hard to spot, but you have no pity. Let ${him} try be locked up for a couple of weeks and see how ${he} likes it.

    *goto exitinter

"Then we'll talk once it's done." You make no promises what you'll talk about. That's not important. Getting away from Ortega would be far easier than jail, you know how ${he} works. One overconfident ${ortega_gender}. "You'd better hope people really haven't heard what we have been talking about, you'd be in trouble then."

"Like I said, I'm confident that they didn't." $!{his} smile is thin but present. "Hang tight and don't make waves. I'll see what I can do."

"It's not like I can do much else." You don't smile as ${he} rises, if there's still a visual of the scene, you don't want to look too friendly.

"I'll be in touch." The nod is nearly imperceptible as Ortega gets up to leave, but there's no trace of levity as ${he} heads to the door. Look like you both have the same idea, tell the LDPD nothing was gained and everything can go back to normal.

For now.

*set jailoutmaybe true

*goto walkback

*label planfailed

"Fine." Ortega shakes ${his} head, giving you this tiny victory."Your plan failed. That's why I'm here."

"My plan?" You can't help the question, ${he} is giving you information for free, but that doesn't help if you don't know what ${he}'s talking about.

"Your kidnapping plot." An annoyed gesture with his hand. "$!{surname} is safe."

"That would imply ${che} was ever in danger." You keep your face blank as you try to add up what this might mean. Has ${he} located your body? Taken it back? Arrested your accomplishes? You need to know the details.

"Oh don't give me that bullshit, ${puppet_name}." Ortega sighs, leaning back on ${his} chair looking every single one of ${his} almost four decades. "I don't [i]know[/i] who you work for, or what your reasons were, but I have my suspicions. And if you're not interested in spending the rest of your life behind bars, then you'd better talk."

"Why not talk to your precious ${surname}? I'm sure ${che}@{sv 've| has} told you everything by now." You smirk, adding salt to the wound. Would be hard to talk to a comatose body, is that why ${he}'s looking for answers? For what might have been done to ${name} to leave ${chim} like that?

*if guiltymc

  *goto dontget

*else

  *goto meetyes

*label meetyes

"I have." Ortega looks tired as ${he} runs a hand through ${his} hair. "With admittedly limited success."

"I'm sure." Your voice is dry, talking to someone in a coma wouldn't be very conductive.

"But ${che} is the reason I came. $!{che} @{sv wants|want} to meet you."

"What?" You blink slowly, confused. You must have misheard, but Ortega looks like ${he}'s said nothing strange.

"Can you blame ${chim}? You tried to have ${chim} kidnapped." A cold smile, as if Ortega doesn't think this is wise, yet is here anyway.

*fake_choice

  #"Impossible," I say, unable to stop myself.

    "Impossible," you say, unable to stop yourself. Your body is in a coma without you there. This must be a trick.

    "It wouldn't be here, of course. I'd have to escort you to a secure location." Ortega glances towards the window, as if ${he}'s more worried about being overheard than ${he} claimed.

  #"${surname} coming here? That sounds unlikely." Try impossible.

    "$!{surname} coming here? That sounds unlikely." Try impossible. Your body is in a coma without you there. This must be a trick.

    "No," Ortega admits."$!{che}@{sv 's| are} no friend of the police. The plan is to escort you to a secure location." Ortega glances towards the window, as if ${he}'s more worried about being overheard than ${he} claimed.

  #"I'm not falling for that one." It's impossible.

    "I'm not falling for that one," you say, not bothering to hide your disdain. It's impossible, your body is in a coma. Whatever trick Ortega is trying to pull, you're not going to fall for it.

    "I'm not lying." Ortega glances towards the window, as if ${he}'s more worried about being overheard than ${he} claimed. "We have everything planned. Not here, of course. I'd have to escort you to a secure location."

"A secure location." You try to calm down, thinking clearly. Even if it is a bluff, a different location would mean a chance to escape. Better than being stuck here. "Where?"

"I can't tell you. Away from prying eyes." A soft smile as ${he} leans forward. "You'll be safe with me, don't worry."

"Fine," you agree. The problem with clever plans like this is that anything can go wrong. And you plan to make sure that happens. Whatever bluff Ortega is planning doesn't matter. What does is if you can use it. "When?"

"A week or two at the most." $!{he} does ${his} best to sound convincing. "I'll try to arrange for it sooner, but there are hoops I need to jump through. In the meantime, hang tight and don't make waves."

"It's not like I can do much else." You don't smile as ${he} rises, if there's still a visual of the scene, you don't want to look too friendly.

"I'll be in touch." The nod is nearly imperceptible as Ortega gets up to leave, but there's no trace of levity as ${he} heads to the door. Look like you both have the same idea, tell the LDPD nothing was gained and everything can go back to normal.

For now.

*set jailoutmaybe true

*set meetingmc true

*goto walkback

*label dontget

"Damnit, don't you get it?" Leaning forward now, less threat, more to convey eagerness and honesty. Ortega really needs some new material, you know ${him} too well to be fooled. "I'm here to give you a chance. Talk to me. Help yourself."

*fake_choice

  #"Help you, you mean." I stay cold.

    "Help you, you mean." You keep your voice cold, focusing on reading ${him}.

    "They don't have to be mutually exclusive." Ortega does ${his} best to sound reasonable.

    *if puppetortega_relationship = "on shaky ground"

      *if ortega_flirting_puppet

        "We cared about each other once."

      *else

        "We were friends."

      "Somehow I doubt that is still the case." You feel your face twitch, but ignores it.

      "Yeah," ${he} admits. "Kidnapping a friend is a hard thing to overlook. Even for me."

  #"No." I smirk. I have the power here.

    "No." The single word feels so good in your mouth. You have the power here when it comes to this. Not ${him}.

    "Really? Is that all you can say?" Ortega doesn't look surprised. More tired. Disappointed.

    "I'd like to think I've been consistent so far. Don't see why it should change now."

    "Fine." $!{he} sighs, running a hand over ${his} hair. "Have it your way."

*if puppetortega_relationship = "on shaky ground"

  "Not going to tempt me over to the side of good?" You can't help it, rubbing it in. "Make some pretty eyes at me and watch me make a fool of myself again?"

  "You'd really think that would work?" There's an honesty to the question that speaks of hope as much as foolishness.

  "No." Your voice is dry. "Not after spending six weeks in this place."

  "Yeah." Is that a look of guilt on ${his} face at last? "Are they treating you alright?"

  "Nothing's especially bad has happened yet, if that's what you're getting at. I hear they save that until prison. When there's less oversight." You speak the last words as if they had been laced with poison.

  "I..." That made ${him} react. Viscerally.

  "You're a Ranger." You bare your teeth, daring ${him} to protest. "You know these things. You work with the cops. Don't tell me you're as stupid as you like to act."

  "This was a mistake." $!{he} looks towards the door.

*if guiltymc

  *goto exitinter

*else

  *goto offermeet

*label exitinter

"Send the Marshal next time. At least he has the good graces to not pretend he's there on anything but business." Since you can't walk away, the only thing you can do is to make sure ${he} does.

"I'll be back," ${he} threatens. "And at that point you've better have figured out what to say. There's more than one way to get the truth out of someone."

*fake_choice

  #"I'm already shaking in my boots," I taunt.

    "I'm already shaking in my boots," you taunt, keeping the smirk fixed on your face.

  #"Torture, drugs... or do you have a stashed telepath?"

    "Torture, drugs... or do you have a stashed telepath?" The last is an open challenge, rubbing salt in an open wound to see if ${he} flinches.

  #"Get used to disappointment." I hold steady.

    "Get used to disappointment." You would have crossed your arms if they weren't manacled.

"I'll tell the guards to treat you better." Ortega gets up from the chair, looking down at you. "Believe it or not, I'd rather we were having this discussion elsewhere. But you seem dead set on being uncooperative."

"What can I say, the manacles makes it hard to be anything but." You jingle the chains. "You could try releasing me and having a polite chat and a drink."

Ortega doesn't even deign that with an answer, ${he} just walks out the door, leaving you for the guards to return.

*goto walkback

*label walkback

*page_break Business As Usual.

*if meetingmc

  You wish you could shake the unease that descended on you the moment Ortega mentioned ${name} wanting to meet you. It's a bluff, of course, but why are your palms itching? Your throat drying up? The chains are heavy around your wrists, clinking as you walk. This is bad. You just wish you knew why.

*if jailoutmaybe

  You should be happy about getting an opportunity like this. Being moved somewhere. Outside the walls. Under supervision, sure, but so many more options. All you need is a single one, you know how to make the most of the chances you are given.

  Chance. You twitch at that, enough that the guards pause and tighten their grip, as if they expect you to stumble.

*else

  It shouldn't make any difference whether Ortega or Chen tries and fails to interrogate you, but in the pit of your stomach you feel that something has changed. The winds have shifted and there's a storm approaching on the horizon. Danger or opportunity? Both? Roll the dice and pray for sevens.

  Dice. You clench your hands as if you can feel them there, the guards tightening their grip as if they expect you to resist.

No. Not yet. You let out a breath and try to force yourself to relax, you need to. You need to be ready.

[i]In a moment, you will look left.[/i]

*if precognition >= 30

  Familiar. You hold your breath.

*else

  What is this? Deja vu?

You feel a wave of nausea, of vertigo, and for a moment you think this might be it. Are you getting pulled back to your body? Was the shock of seeing Ortega all it took? Your breathing quickens, cold sweat breaking out, and the guards have to support your weight.

Their voices comes from so far away. Deep under water, ripples in the sky. Breathe. They shake you, and you feel like jelly, your self rippling in your body but remaining stuck.

To the left, a door opens, revealing a small break room behind it. More guards alerted by the others, ready for what trouble you will bring.

[i]In a moment, you will look left.[/i]

*if precognition >= 50

  [i]You shouldn't. Don't. No.[/i]

You turn to look, catching a glimpse of a small television screen bleeding color and noise. The air is thick but you see what's on the screen with crystal clarity. News. Footage. No sound.

*if suit_cape

  A sweep of a cape.

A familiar silhouette. A fight? Yes, ${villain_name}

*if suit_strength

  lands a kick,

*else

  sidesteps a blow,

sending one of the LDPD's powered goons flying into a parked car. The camera shakes, then holds steady. [i]You don't remember this.[/i] You don't remember this.

You don't [b]remember[/b] this.

"Stop making trouble." One of the guards yanks you to your feet hard enough that the pain tears you back into the here and now.

"Think ${phe} might throw up." Another guard, but you look past him at the screen as it switches to the weather.

This was news. Current.

*fake_choice

  #This can't be real.

    This can't be real. Whatever that was on the television must have some other explanation. You try to tear yourself free to look again, but the door is mostly shut, and the third guard is helping wrangling you to your feet to get you back to your cell.

    YOu feel numb. In shock. You don't resist their unkind hands as they drag you back to where you belong.

  #"Wait, what was that on the news right now? Tell me!"

    "Wait, what was that on the news right now? Tell me!" You shout your demand at the guard who just exited, but he doesn't even look at you.

    "Shut up," barks one of the guards, giving you a push.

    "No, tell me!" You try to put your will behind the command, but this body has no telepathic powers, and all you get in return is a laugh and a fist in your stomach hard enough to make you gasp for breath.

    You don't fight as they drag you back towards your cell.

  #This is too much. I snap and attack them.

    It's stupid, you know that, but your body isn't listening. Panic. Confusion. Anger. Too much emotion for one skin, and you throw yourself hard enough against one of the guards that he lets you go. Gives you an opening you repay with an elbow in the gut.

    *if precognition >= 40

      He gasps for breath.

      [i]Hands from behind.[/i]

      You throw yourself forward, the hands reaching for you barely missing. There's no way to run with these chains, and you don't have the reach for proper blows. But you do have your body, and tackles the guard in front of you to the ground.

      [i]A boot being lifted for a kick.[/i]

      Instead of pressing your advantage you roll to the side, using your chained legs to sweep the leg of the guard behind you that was about to kick you. He falls, hard, and you hear a crack as his head hits the floor.

      [i]Left. Danger.[/i]

      You roll right, avoiding the fallen guard reaching for you. You need to get to your feet fast, but with your hands and feet chained like this that is easier said than done. It's only a matter of time before they restrain you, you know that with bone-deep surety. All you can do is to make them pay, giving as good as you get.

      By the time they finally have you under control, they are bruised and bloodied and you are grinning.

    *elseif puppet_skill = "aikido"

      You don't have the reach for blows with your chains, but you're good at working with what you have. Leverage. A knowledge of which parts of the human body hurts the most.

      Steel-toed boots doesn't leave anything open, but folding a leg behind one of theirs lets you push one of the guards to the ground. Enough reach to slam the chains into his face, blood, broken nose and lips. He screams, it feels good, and then hands behind you drag you back.

    *elseif puppet_skill = "boxing"

      The chains restrict your arms, but you don't need much reach for a jab, a body blow with both your hands. The guard leans forward, gasping for breath and you slam your forehead into his.

      You both see stars, but you were ready for it, and his nose is broken as he stumbles back. Good. You want to hurt him. You need to hurt someone to get this helpless frustration out of your system, but rough hands drag you back before you can press your advantage.

    *else

      You're not a fighter, but you know what hurts. Rough arms grab you from behind, so you let them hold you as you pull your legs up, kicking like an angry horse.

      Your feet connect, pushing back the first guard hard enough to make him stumble. Fighting for breath, and if you could you would have kicked him in the groin, but you're held back, all your flailing amounting to nothing.

    What ensues is not pretty. Nor kind. Still, the pain is preferable to the complicated terrors that shot of ${villain_name} awoke in you. Drown the fear in adrenaline and the anxiety in bruises, you can deal with being beaten up. They're not going to kill you. Nor hurt you enough that the Rangers will have cause for complaints. Most of the bruises will be hidden under your clothes.

    *set puppet_status "bruised"

    *fake_choice

      #I play up the pain to make them stop.

        To hell with dignity, right now you want to keep yourself as intact as you can. Even if that means playing up the pain while trying to make sure their kicks and blows doesn't hurt anything vital. They want to hurt you, and giving them proof of that will make them tire faster.

        Not the first time you have put on a show like this. You know better than trying to appeal to their humanity, make them feel sorry for you. They won't. That's not the kind of people that work here.

      #I know how to roll with the punches.

        You know how to roll with the punches. Make it seem that the blows connects harder than they do. The chains are a hindrance, but luckily they try to avoid your face. Body blows are easier to mask, both for you and for them.

        Not the first time you have put on a show like this. Make people feel they have the upper hand, offer them openings where you can control the result. These are brutes, not fighters.

      #I fight until the end.

        It is stupid to keep resisting, to try to get a final kick or headbutt in. But you keep trying. Keep cursing them. Someone puts a hand over your mouth and you bite down hard. Taste of blood. A scream. That gets you a proper blow that sends you to the floor, head ringing.

        No explaining away the black eye you can already feel starting to swell. No stopping the half laugh, half cough that has you spitting blood over the floor. Yours and his.

        *set puppet_wound "has a black eye"

    In the end, it doesn't matter. You get dragged back to your cell all the same, giddy with pain and adrenaline.

  #This is too much. I throw up.

    You can't help it, the implications land in your gut, making it turn itself inside out. Your panic splatters the floor, and the guard's boots.

    They don't approve of that, but their curses as they drag you back towards the cell feels distant. Numb. You remember breathing and things clear, though your anxiety does not.

Rough hands removes your chains, and then the cell door locks behind you.

Alone.

*if puppet_status = "bruised"

  You wipe your lips. Try to swallow the taste of blood. Sore. Hurting. No serious injuries. Your rubs smart, but you don't think they're cracked. You can breathe alright, so you do that as you wait for the adrenaline to fade so you can think.

*else

 You breathe. Count to five. Ten. Twenty. Think.

The television footage you saw must have been on the news. It adds up with the two o'clock slot. No sign that it was a retrospective of a battle you would somehow have forgotten. No reason to put that on the afternoon news. And there is no way you could confuse your armor with someone else. That was ${villain_name}, not a copycat.

Breathe.

*if puppet_status = "bruised"

  Focus on the pain in your side.

*if rangersarmor

  As far as you know, the Rangers have your armor. You doubt that anybody has stolen it from them, which means that this might be a trick. Some way of influencing you to talk. React. It could be anyone in there.

  *if animatedarmor

    Wait...

*if animatedarmor

  You have seen your armor move before. When it saved you. Controlled by the Rat King. Could that be it? It makes sense, the clip was too short for you to analyze movement. But why? Could the Rat King be out looking for you? They are telepathic, of course they would realize if your head was empty. They've seen you shift back and forth between yourself and the puppet enough times?

  Could the Rat King be that smart? The girls might be rats, but their brains have been joined together before they even remembered having bodies. How much have they learned?

*elseif boss

  Could it be one of your crew in there? You don't think so, they're not exactly telepathically sensitive. The baseline functions should still be available, sure, but enough to fight like that? Of course you didn't see the end of the fight, just one clip, little enough that it might have been anybody in there.

*else

  Could it be ${hench_name} in there? You don't think so, ${hhe}'s not exactly telepathically sensitive. The baseline functions should still be available, sure, but enough to fight like that? Of course you didn't see the end of the fight, just one clip, little enough that it might have been anybody in there.

Why though? An attempt to make sure that everyone knows that ${villain_name} is still active? Keeping up your reputation? Getting cash to pay for your body's treatments?

Or maybe you're wrong. Maybe someone did steal it. Your armor. Your identity. You wouldn't be the first villain who fell victim to that, even if your circumstances are stranger than just having been arrested.

You don't know. You can't know. And you can't [b]do[/b] anything about it.

Nothing. You're helpless.

*page_break Trapped.

That night you wake up sweaty from unremembered nightmares, wandering unfamiliar labyrinths trying to find what you've lost. But you didn't remember what it was, too busy with trying to put back the bodyparts that kept felling off. You had to check your teeth when you woke up.

Still there.

Past slides into present like dreams into wakefulness.

*if precognition < 30

  You feel like you woke up on the verge of understanding something significant. Still your hands are unsteady, the shiver remaining. Touched. By something.

  *set precognition 30

*elseif precognition >= 50

  It's coming. Your opportunity. Breathing down your neck, close enough to almost be smelled.

*else

  Something. Something on the tip of your tongue. You can almost taste it.

Disinfectant. [i]A flash of a doctor's office, no, of the corridor leading to it.[/i] Taste it. Smell it. Clean. Linoleum floor. [i]A hint of daylight through reinforced windows, the bars lining the floor like stripes.[/i] What?

You shake your head, looking at your own floor. Dark. Polished concrete. You could see the other floor so clearly. Focus.

[i]Shadows. Yours. A guard. A third shadow outside the window. And then the wall is gone and the noonday sun floods inwards as the screams begin.[/i]

You can see it clearly. More clearly than the dream. You know that corridor. It leads to the doctor's office, though it's really just a nurse that's on call. You were taken there for a checkup once, to tick off some box on a form to show that you were treated well.

[i]Your shadow on the floor, no bars now, just an encroaching darkness.[/i]

*fake_choice

  #That's where I need to be, I know it.

    You've had glimpses of what might be the future before. Hints of things that might come to pass. Nothing is written in stone, but this felt like an opportunity. You need to be there to take advantage of it.

  #A chance to escape? It must be.

    This is how you get out of here, you know it. You've had flashes like this before, and you've learned to trust them. This will be your chance to escape, you know it. That corridor. You need to be there.

  *selectable_if (precognition = 30) #What is happening to me?

    What is happening to you? This feels new and portentous in a way that reminds you of how you felt when your telepathy first started leaking through. Knowledge first, then understanding. You need to trust this. Trust your reactions. This might be a chance to escape, but you need to be there to make it happen.

You can feel it in the pit of your stomach. A premonition. Tomorrow is the day. You need to [b]be[/b] there.

*if puppet_status = "bruised"

  It won't be hard to fake needing to visit the nurse. Not after the beating the guards gave you.

*else

  You need to fake a reason to visit the nurse. Stomach pains would be the easiest, perhaps spitting some blood. Nobody wants to deal with a sick prisoner if it can be avoided.

The Rangers still visit you. Need you. You doubt the guards wants to take the chance to annoy them, no power trip is worth that hassle.

It could work. No, and you know this in the deep pit of your stomach, it [i]will[/i] work.

It's surprisingly easy to go back to sleep.

*page_break The Morning Is Inevitable.

The next day starts early as always, and you prepare for what is to come by pretending to be sick. Looking weak and nauseous is not hard, a bit of moisture on your brow gives you that look of cold sweat. Picking through your breakfast you leave most of it uneaten, keeping up appearances in front of the camera.

*if puppet_status = "bruised"

  By now your bruises have grown, and you make a note to pull up your shirt to look at the remnants of the body blows you received.

Touching your stomach as if you're in pain.

It's weird, this tingling anticipation. Like a slow-motion fight, where predicting the next blow doesn't happen within the fraction of a second, but over the course of minutes and hours. You're starting to get a feel for it, how to listen to that inner voice when it's time to do something.

Put yourself on the knees in front of the toilet, pretending to throw up right as the guards arrive, forewarned by the knowledge that this is the right moment.

*fake_choice

  #"I really need to see the nurse," I beg weakly.

    You know that while you are in ${puppet_name}'s body, you're charming. Attractive. Convincing. What' you're going for is different from your normal manipulative methods of confidence and flattering attention. Can you look pathetic enough to make a hardened LDPD guard react?

    "I really need to see the nurse," you mumble, sitting on your cot, holding your stomach.

    *if ${puppet_gender} = "woman"

      "Please, something is wrong." You give the guards a dose of your most soulful and desperate eyes, keeping them wide enough that the exposure makes them tear up. A little bit if shine, a shiver of your lower lip. "It hurts."

    *else

      "Something's wrong. Not kidding there." You do your best to walk the line between looking weak enough that they'd take you seriously, but not pathetic enough that they'd only feel contempt. You'd been in control so far, at least as much as you've been able to under these circumstances, but now? That look of fear in your eyes, the shiver of pain as you bite your lower lip? That could only be real.

  #No need to pretend throwing up, I can do that on command.

    It's not hard to vomit if you try to, it's been a useful skill to have if you suspect you've been poisoned. Or when you want to get out the pills before they take effect. You can even do it quietly, but this time you are going for loud and gross. Predictably the footsteps outside the cell slows, and you can hear sympathetic grunts of disgust. Humans are pack animals, if one of the pack is sick, chances are the rest might have eaten something bad too. As contagious as a yawn, but twice as gross.

    "I don't feel so good," you mumble as you turn to look at them, leaning on the toilet without flushing. Something dribbles down your chin and you're sure it's not saliva.

  #I bite my cheek to dribble some blood down my chin.

    As you push down the handle to flush and hide the lack of evidence, you let saliva and blood dribble down your chin. Your cheek hurts from the bite, but it's for a good cause.

    The look on their face as you turn towards them is priceless. Disgust. Worry. "I don't feel good," you mumble, wiping your chin, which only smears the blood further. You keep leaning on the toilet as if that's the only thing holding you upright.

"Shit," one of the guards mutters.

*if puppet_status = "bruised"

  "I told you they went to far."

"What's the problem," the shorter guard says, voice raised as she approaches the cell. "Speak up."

"My stomach," you answer, doing your best to make your voice tight with pain, nearly hyperventilating. "It's getting worse."

"You make a mess in there, you clean it up," she retorts, unsympathetic. Not so the first guard.

"Let's get ${phim} to the nurse. You know the Rangers are interested in ${phim}. I'd rather not be chewed out for doing nothing." Better to dump the problem on the medical staff. You can see the other guard nodding thoughtfully as you bite back a whimper and let some saliva dribble out in long, disgusting threads.

"Assume the position," she barks, suddenly impatient.

"I'll try." You pull yourself to your feet, knees wobbly. A few unsteady steps later and they can put the chains on you like always. That should be a problem, but you know it's not.

[i]Your wrists burn, the air smelling like formic acid.[/i]

"Come on, try to keep things down." The first guard helps you out of the cell, making sure to stay to the side and behind. Hardly touching, as if they fear you're contagious. Which you might as well be.

*fake_choice

  #Am I a fool for thinking this can work?

    You can't help feeling unsure, even with the looming weight of visions bearing down on you. What if you're just having a psychotic break?

    You can't really be seeing the future, can you?

  #I need to focus, what do I need to do next?

    You let your eyes drift close as the visions hover behind your eyelids. No defining moment, no break in the flow. Just the endless ticking of time, drops of water on an umbrella.

    Is something trying to connect?

  #I'm calm, like deep water. Things are in motion at last.

    You pretend weakness and anxiety while your mind is calm like deep water. Only the surface moves, everything down here is clear and dark, heavy with purpose on your chest.

    The world is moving towards you as you are standing still.

${puppet_name} is a boost. You're certain now.

*if ace

  You've suspected since you saw the video Dr. Mortum showed you. But now you're starting to wonder if it really can be precognition? Not probability manipulation, or luck, or something similar. Precognition. Know what will happen before it does.

*else

  It would explain everything. The coma. Could that have been when the boost kicked in? If your puppet has some form of precognition, did it come in all at once? Strongly enough to wipe ${phis} mind with too many possibilities?

A dangerous power. Are you seeing the truth or options? You sure are not seeing context. Not can you summon it on command. And yet...

[i]A flash of the corridor leading to the nurse's office. A hint of disinfectant cutting through the smell of your own unwashed body.[/i]

Not there yet. Still on concrete floors. The ticking of bars sliding open as you pass through the doors. Wait until the ones behind you close before the ones in front of you opens.

Your heart pick up speed, and you don't bother to hide your shallow, nervous breaths. Something strains inside you, spoon failing to scoop out the inside of an egg.

[i]A hint of daylight through reinforced windows, the bars lining the floor like stripes.[/i]

Up ahead. A hint of daylight shines through the reinforced windows, the bars forming a striped pattern on the floor. You don't have to fake the nausea now, the future approaching the present like an avalanche.

"I need to throw up," you mumble, only half a lie as you step into the future, matches steps unto your shadow become yours, and you fall to your knees in the corridor.

Nobody catches you, the guards taking a step back to avoid any splatter. Nothing to worry about for them, you can't run anywhere in these chains. And even if you did, there's no way out. For long.

*fake_choice

  *selectable_if (precognition >= 50) #Everything is clear as crystal, I [i]know[/i] what do do.

    Everything turns clear as crystal, the world slowing down around you as things click into place. A shadow outside the window, you see it on the floor and roll up against the wall. Right where you need to be.

    [i]A smell of formic acid, burning wrists.[/i]

    You ignore the terrifying implications and press your manacles against the wall as the guards stand strangely immobile, as if they can't quite understand what's going on. The blank stare of people listening to someone else's voice.

  #A shadow outside, that comes next, right? Right?

    You think you remember the dream, a looming shadow outside, crossed by the bars on the floor. Being seen would be bad, so you roll to the side, pressing yourself against the wall.

    The guards do not move to stop you, instead they stand strangely immobile, looking blankly at the floor. Listening to someone else's voice.

  #The wall is going to fail, I hide against it.

    The wall is going to fail. You know it by the ache in your gut, pretension turning real as you try to stay in the moment. You throw yourself to the floor and roll against the wall just in time to see a looming shadow on the floor, still trapped by shadow bars. Not for long.

    It's strange how the guards do nothing to stop you, they stare blankly into place, as if they are listening to someone else's voice.

  #No. No. [b]No[/b]. This can't be right...

    The dread descends like nightmares. You suddenly [i]know[/i] what is happening. [i]Who[/i] is approaching. And you can't. You can't. You can't. So you do what you can, you throw yourself to the floor and roll to the wall. Out of sight from the window just as the shadow appears, still outside. Not for long.

    The guards ignore you as you knew they would, staring straight ahead like unseeing statue. Listening to a voice you can't hear.

There is a thump as something heavy hits the wall, though you know the loudness is only in your mind. Layers of concrete, reinforced against explosions, ramming cars and exo-armors. Not high-security, but secure enough for most purposes.

Not this one.

The smell hits you first, the formic acid of memories, nobody would notice if they didn't know what it meant.

*page_break Nanovores.

Time slows. The moment holds. The guards stand immobile. The wall is there, but you know that in a moment it won't be.

Concrete. Insulation. Rebar. Rebar? Yes!

You hold your shackles and chains tight against the wall, praying that the nanovores won't care about the difference between rebar and steel, that they have been commanded to make a hole. You know the importance of control, how hungry they get, half-starved on their inorganic diet. It would take the finest of touches to pull them back immediately, and you hope that's not the case here.

It can't be. It won't be.

Daylight floods the corridor as the wall disappears, the smell strong now, scouring your nostrils, the sting around your wrists gentle nettle-marks as the manacles fall away, chains partly devoured together with part of your prison jumpsuit.

[i]In a moment, the shadow will shift and a hand will reach down for you.[/i]

But that is one moment from now, so you still have time to act. Avoiding the hand won't be hard, but what next?

*comment no daring, puppet_skill or similar added yet. Will be in the demo. So you won't know how to solve this yet. Also, no IP variations yet. Don't forget to add "ratfail"

*fake_choice

  #I scramble back and get to my feet, ready to run.

    The shadow shifts, and right on cue you roll away, avoiding the armored fist as it reaches for you. Reaching. Not a blow, that is good. Your breath quickens as you scramble back, getting enough distance to get to your feet and take in what stands before you.

    *gosub villaindescription

    Should you run? The hole in the wall is a beacon of hope and freedom, but

    *if precognition >= 50

      —

      [i]— the arm slamming into you smacks the air from your chest, sending you spiraling to the floor.[/i]

      A bad future. You can't let that become your present.

    *elseif tactician

      you know better than to go for it. Predictable.

    *else

      the moment that thought hits you feel nauseous. You've seen a hole like this beckon before, a window, a way out.

      You won't fall for it this time.

    Instead, you retreat, keeping the frozen guards between you and ${villain_name}, looking for the opening you know will come.

  #I scream loudly, trying to attract attention.

    The shadow shifts, and right on cue you roll away, avoiding the armored fist as it reaches for you. Reaching. Not a blow, that is good. Your breath quickens as you crawl back, looking up at what stands before you.

    *gosub villaindescription

    A moment. Not more than that. Then your paralysis breaks and you scream. Loudly, as desperately as you can. You're in a building filled with LDPD officers, there are cameras everywhere. And if they are out, screams carry. Someone will investigate, all you need to do is keep away until then. You hope.

    In the meantime, all you can do is to scramble to your feet, keeping the frozen guards between you and ${villain_name}. Hoping help will come.

  #I hit one of the guards, trying to snap him out of his daze.

    The shadow shifts, and right on cue you roll away, avoiding the armored fist as it reaches for you. Reaching. Not a blow, that is good. Your breath quickens as you scramble back, looking up at what stands before you.

    *gosub villaindescription

    This is bad. You force yourself to break the moment, using one of the guards to get to your feet. If you could rouse them you'd at least have a distraction so you slap him hard, with all your force. No reaction.

$!{swear}. You don't get the feel that this is a friendly rescue, whatever is in there feels hostile. A threat.

*if suit_speed

  You know how quick the ${villain_name} armor is, the constraints of the corridor will hamper it somewhat, but the moment you escape to the streets that advantage will be gone.

*elseif suit_strength

  You know how strong the ${villain_name} is, if you're caught there will be no escape. A mistimed blow could kill you, assuming that isn't already the goal. You have no room for mistakes.

*else

  You know how reinforced the ${villain_name} is, there's nothing here that could even scratch the paint. Your only chance is avoiding it for as long as you can.

You need to get out of here, but how?

The moment you think that thought, that's when the guards begin to move. Turning towards you, eyes still blank, hands outstretched. Controlled.

Of course. Not like your day could get any worse.

"Afraid to put your hands on me?" you say, bravado in the face of certain doom as you desperately try to come up with a plan.

*fake_choice

  #I will trust my precognition to get me out of this.

    *goto precog

  #Your powers are too unreliable, I need to solve this on my own.

    *goto noprecog

*label precog

So far, your precognition has been handy, but can you trust it to work when you want it to?

*if motivation_fate

  You feel your mouth twisting into a smile. Of course you can. This is not your end, you might not know the details, but of that you are sure. All you need to do is stop worrying and trust your instincts. You don't control fate, fate controls you.

  *set precognition %+ 10

*if arrogance <= 30

  You can't force the future to bend to your will, that's for sure. Some humility is needed here. Being open to possibilities you might not have planned for.

  *set precognition %+ 10

*if precognition >= 50

  It's like the early days with your telepathy. Don't push it. Let it come to you.

*else

  The nervous weight in your stomach doesn't shift, so you swallow it and try to focus.

At least you don't need any help avoiding the approaching guards. They are slow and clumsy, more walking dead than the fine instruments you wield.

*if suit_telepathy

  Is whoever is in the suit using the telepathic enhancers to boost what meager powers they might have? Must be.

*else

  That they can do it at all is worrying. They must have some form of telepathic powers.

*if precognition >= 60

  [i]A hiss of compressed air, the armor opening, a growl of frustration as you run.[/i]

  You blink, back in the present, backtracking the path needed for that future. Time. You need time to get a headstart. The forced opening/closing cycle is not instant. It takes precious seconds to complete.

  And it can be accessed from the outside.

  It was a security measure installed in case you needed to free your unconscious body as your puppet. Gritting your teeth you barely dodge ${villain_name}'s arm by stepping in, instead of retreating. Down and left, under the side, the spot you need is exposed for a moment as the arm is outstretched.

  There! You push the access hatch hard enough that you nearly stub your finger. It opens, so you immediately press down the release switch as hard as you can.

  *goto opensesame

*else

  You growl in frustration as one of the guards nearly grab you. Whatever future you're looking for is not there, out of reach, as impossible to read clearly as Ortega's thoughts in one of your endless training matches. The better you got at telepathy the harder ${he} became to beat, the more you relied on augmented reflexes the more infuriating ${his} wins. The tide turned back once you learned ${his} tricks, but there's no time for that here.

  You need to leave. Now.

  *goto badrun

*label noprecog

So far your precognition has been handy, but you can't trust it to come when you need it to.

*if precognition < 40

  Too unreliable, there's been no pattern in what it has shown you so far.

*else

  If you get another feeling, good for you, but you need to act now.

If there's anything you've learned over the years is that you make your own luck.

*if tech_savvy

  Why did ${villain_name} send the guards to get you? They're slow, stumbling, they're not hard to avoid. Why not grab you right away?

  Why would they be wary? Do they suspect you know more about the armor than they do? It would make sense, ${puppet_name} was the one who dealt with Dr. Mortum, and the plans to make it.

  Huh. Maybe they are right to be worried.

  While the armor itself is impervious to your bare hands or the guards' sidearms, there is a hidden emergency release. You put it in to be able to open it from the outside, if you ever were badly wounded, your puppet would need access.

  Could you get to it safely? Or, at least, while avoiding being grabbed?

  No time to think about it, you dodge under the arm of one of the guards, they are slow and clumsy, not the fine instruments you wield.

  *if suit_telepathy

    Is whoever is in the suit using the telepathic enhancers to boost what meager powers they might have? Must be.

  *else

    That they can do it at all is worrying. They must have some form of telepathic powers.

  [i]The hand will reach for you—now![/i]

  You dodge the grasp by stepping in, instead of retreating. Down and left, under the side, the spot you need is exposed for a moment as the arm is outstretched.

  There! You push the access hatch hard enough that you nearly stub your finger. It opens, so you immediately press down the release switch as hard as you can.

  *goto opensesame

*else

  Why did ${villain_name} send the guards to get you? They're slow, stumbling, they're not hard to avoid. Why not grab you right away? Don't they have full control of the armor? Are they worried about hurting you? Good. That means they want you alive.

  That also means you have a moment or two to plan. The sidearms the guards carry won't be any use against that armor, but they carry something else that might.

  Communicators.

  Dodging clumsy hands, you grab the communicator. No use calling a general alarm, if the people here were capable of helping they would already be on the way. No, you punch in a code you shouldn't know, thank Mayor Alvarez for the new integrated systems, and speak loudly as you back away.

  "Code Orange at the LDPD holding facility. Walls breached, exo-armor intrusion. Urgent assistance needed." You fake a cry of pain and throw the communicator against the wall before anybody can ask any questions. It breaks with a hiss.

  Good. Now it's just a matter of time.

  *goto backup

*label villaindescription

*if suit_terrifying

  What. Not who.

  The

  *if suit_cape

    cape billows behind it, as the

  creature steps into the corridor. Heavy footsteps, metal on concrete giving the impression of claws sharp enough to tear you open though you know that's just your imagination. Even though you intellectually know exactly who this is, your body reacts with the instincts of a cornered animal in the presence of a predator. A nightmare.

  Infrasound. Vocal distorters. The audioscape is as nauseating as the visuals.

  $!{villain_name} stands before you in all its terrifying glory, and all you want to do is run.

  *return

*elseif suit_imposing

  No. Not what. Who.

  The

  *if suit_cape

    cape billows like a flag of war as the

  armored warrior steps into the corridor. Heavy footsteps, loud enough in this enclosed space that you almost expect the concrete to crack. It's an illusion, you know that. The armor is not that heavy. You've just never been on this end before, cowering like a weak, fleshy thing before the approaching conqueror.

  $!{villain_name} stands before you at last, and all you want to do is run.

  *return

*elseif suit_mysterious

  It takes a moment for you to grasp fully, the

  *if suit_cape

    cape billows as the

  cloud of smoke obscures the outlines. The mirrored helmet reflects the surroundings, concrete and smoke, and you're not sure of the outline of the armor.

  You reflexively hold your breath before the fact that the guards remain upright makes you realize the smoke is just for show. Of course.

  $!{villain_name} wouldn't step into the dragon's lair without always liked making a show of things. However, the smoke works both ways, and you freeze as if the mist can hide you too.

  *return

*else

  No. Not what. Who.

  The

  *if suit_cape

    cape billows as the

  armored intruder steps into the corridor, a nonchalant glance to get an overview of the situation. No grandiose gestures, just minute movements giving clues to who is really in control here for the people who know how to look. You do. You know better than to fall for the understated impression the intruder cultivates like armor.

  $!{villain_name} is nobody's fool, and when the head turns to look at you, you find yourself freezing like a dear in the headlights.

  *return

*label backup

"Hear that?" you say to ${villain_name}, doing your best to sound more confident than you feel. "You're running out of time."

Whoever gets sent, they at least will be able to delay and distract. The bigger issue will be to try to keep away until they do, already your words have made ${villain_name} straighten up and take notice.

$!{swear.} Maybe taunting wasn't the right choice.

*if suit_speed

  You know that stance, the faint hum of ${villain_name}'s armor gearing up to [i]MOVE—[/i]

*else

  $!{villain_name} take a decisive step forward, you need to [i]MOVE—[/i]

You throw yourself to the side just in time as a man-shaped blur impacts ${villain_name} hard enough to

*if suit_armor

  nearly topple them before ricocheting into the wall.

*else

  slam them into the opposite wall.

The air fills with smashed concrete, the dust obscuring the scene briefly before you can make out what just happened.

"Gettosafetynow!" The words run together enough to be a continuous blur, and they're not aimed at you. At the guards, who shake their heads in confusion, free from control at last. The impact must have rattled ${villain_name}.

You doubt Zephyr can do much else.

The Guardians

*if blazedead

  new leader and

resident speedster is quick on the scene, you'll give them that. But going up against ${villain_name} on their own? Not a chance.

*fake_choice

  *selectable_if (suit_speed) #Though their speed removes one of my best weapons.

    You hate to admit it, but Zephyr's speed does remove one of your armor's great advantages. $!{villain_name} is fast, but Zephyr is faster.

 Not that it matters, all you need for them is to focus on each other so you can get away.

  #I don't need them to win. A distraction is enough.

    You don't need Zephyr to win, and you have no expectations they will. They're here to buy time into the rest of the team arrives, and by then you'll be gone.

  #Never thought I'd be happy to to see one of the Guardians.

    You never thought you'd be happy to see one of the Guardians, but right now you are. This means you'll have a chance to escape, whatever Zephyr's faults might be, they are too fast to dare take your eyes off.

"So quiet ${villain_name}," Zephyr keeps talking as you move, the two of them are facing each other, hero and villain. Nice shot if you would have had a camera. "And they say you're so chatty."

You're half tempted to shout that's because it's not you in there, but you keep your mouth shut and make a run for it. $!{villain_name} aims a threatening gesture in your direction, you can nearly feel the frustration when you don't react and keep running. As if you'd be intimidated by that. Zephyr's earlier move have led to the hole in the wall being accessible, and this time you don't hesitate as you leap through it.

You can only home you'll manage to get far enough away in time.

*comment continue here, variants, add dialogue to some. Puppet_skill additions.

*label opensesame

The hiss of compressed air is as familiar as your own breath, and you can hear a muttered curse, chopped to syllables by the vocal distorters as the armor begins its opening cycle.

You wish you could stay and see, be face to face with this thief and impostor, and possibly sock them one. But you only have a few seconds, and you intend to make the most of it.

$!{villain_name} stumbles to the side as the armor begins to partially open, shielding the chest and face from the cameras. Just the opportunity you need.

You leap through the now undefended hole in the wall, running as fast as you can. You won't have long, you have to make the most of it.

*comment continue here, temptation to watch? Too divergent?

*label badrun

*comment collected headline for all fuckups. Write later.